IModelling.Ols

Syntax

Ols(Input: ITimeSeries;

Period: IMsPeriod;

ConstantValue: Variant;

AROrder: String;

MAOrder: String;

Casewise: MsCasewise;

Explanatories: Array): Variant;

Parameters

Input. Output variable.

Period. Period, at which the method is calculated

ConstantValue. Constant used in calculations.

AROrder. Autoregression order.

MAOrder. Moving average order.

Casewise. Missing data treatment method.

Explanatories. Explanatory variables.

Description

The Ols method models a variable with the help of linear regression (OLS estimation).

Comment

The Ols method should be used only on series calculation mode.

Features of setting parameters:

Period. If the parameter is set to Null, the method is calculated at the entire time period
ConstantValue. The value of the constant can be determined by the user or estimated automatically. Use the IModelling.Estimate method to estimate values automatically. If the model should be calculated without constant, use the IModelling.None method
AROrder, MAOrder. Parameters are set in the string view. Specify the numbers or ranges of autoregression or moving average orders separated by commas. The range of autoregression or moving average orders is specified via the sign -. For example: AROrder = "1-3,5"
MAOrder. If the moving average order is set, back-casting can be used to estimate its coefficients. Back-casting is used by default. If back-casting must be disabled, the MAOrder parameter must contain the string "backcast.No". For example: MAOrder = "1-4;backcast.No"
Explanatories. Terms, corresponding to variables, are specified via comma. Note that the number of explanatory variables (m) should satisfy the inequality: 0 < m < n-1 for a model with constant, and 0 < m < n for a model without constant, where n - number of observations in the output variable.

Example

Executing the example requires that the repository contains a modeling container with the MS identifier. This container includes a model with the MODEL_D identifier that is calculated by the determinate equation method and contains more than one input factor.

Add links to the Metabase and Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Inp_1, Inp_2: String;
    Expr: IExpression;
Begin
    Mb := MetabaseClass.Active;
    ModelSpace := Mb.ItemById("MS").Bind;
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.Pointwise;
    Inp_1 := TermInfo.TermInnerText;
    TransVar := Transf.Inputs.Item(1);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.Pointwise;
    Inp_2 := TermInfo.TermInnerText;
    Expr := Determ.Expression;
    Expr.References := "Ms";
    Expr.AsString := "Ols(" + Inp_1 + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" +
        "), Estimate, """ + "1" + """, """ + "" + """, MsCasewise.Yes, " + Inp_2 + ")";
    If Expr.Valid Then
        ModelObj.Save;
    Else
        Debug.WriteLine("Model is not saved: error in formula");
    End If;
End Sub UserProc;

After executing the example the model models the first input variable using linear regression (OLS estimation) at the period 2000-2015. The value of constant is estimated automatically. Calculation is executed using the Casewise missing data treatment method.

Example of Use in Expressions

Expression 1:

Ols({Brazil|BCA[t]},SetPeriod("01.01.2002", "01.01.2015"), None,"","", MsCasewise.Yes,{China|BCA})

Result: the Brazil|BCA series is modeled by the linear regression method (OLS estimation) at the period 2002-2016 by the following parameters: constant is not used, autoregression and moving average orders are not set, explanatory variable is the China|BCA factor, calculation is executed using the Casewise missing data treatment method.

Use: it can be used in formulas of cross functional expression editor in any platform tool where it is available.

Expression 2:

Ols(X1, Null, Estimate, "1", "2;backcast.No", MsCasewise.Yes, X2, X3)

Result: the X1 factor is modeled by the linear regression (OLS estimation) method by the following parameters: constant is estimated by the IModelling.Estimate method, autoregression order is 1, moving average order is 2, backcasting is not used to estimate moving average coefficients, explanatory variables are X2 and X3 factors, calculation is executed using missing data treatment by the Casewise method.

Use: it can be used in model formulas of modeling container based on variables.