IMetabaseUpdate.SaveToFileNFEx

Copy example

Sub UserProc;
Var
    MB: IMetabase;
    Update: IMetabaseUpdate;
    UFN: IMetabaseUpdateFolderNode;
    UON: IMetabaseUpdateObjectNode;
    Progress: IMetabaseUpdateProgress;
Begin
    MB := MetabaseClass.Active;
    // Create an update
    Update := Mb.CreateUpdate;
    UFN := Update.RootFolder;
    // Add object to update
    UON := UFN.Add(MetabaseUpdateNodeType.DataObject) As IMetabaseUpdateObjectNode;
    UON.Object := MB.ItemById("ALGO");
    // Create an object to handle events
    Progress := New MyUpdateProgress.Create;
    // Save update to file
    Update.SaveToFileNFEx("D:\Work\Algo.pefx", Progress);
End Sub UserProc;

// Class that implements events that occur during creating an update
Class MyUpdateProgress: UpdateProgress
    // Event that occurs before saving custom objects to file
    Sub OnBeforeCustomObjectSaveToPef(Resolver: ICustomObjectResolver);
    Var
        Refs: IMetabaseCustomObjectReferences;
        Ref: IMetabaseCustomObjectReference;
        XmlVar: Variant;
        XmlDoc: IXmlDomDocument;
        i: Integer;
    Begin
        // Display basic information about custom object
        Debug.WriteLine("Object class: " + Resolver.ClassId.ToString);
        Debug.WriteLine("Name: " + Resolver.Name);
        Debug.WriteLine("Description: " + Resolver.Description);
        Debug.WriteLine("Identifier: " + Resolver.Id);
        Debug.WriteLine("Key: " + Resolver.Key.ToString);
        // Display information about object dependencies
        Refs := Resolver.References;
        If Refs.Count > 0 Then
            Debug.WriteLine("Object dependencies:");
            Debug.Indent;
            For i := 0 To Refs.Count - 1 Do
                Ref := Refs.Item(i);
                Debug.WriteLine("Object: " + Ref.Object.Name);
                If Not IsNull(Ref.Owner) Then
                    Debug.WriteLine("Owner: " + Ref.Owner.Name)
                End If;
            End For;
            Debug.Unindent;
        End If;
        // Read data from object to XML format
        Resolver.ReadToXML(XmlVar);
        // Present read data as a document
        XmlDoc := XmlVar As IXmlDomDocument;
        // If document contains data, display it in the console window
        If (XmlDoc <> Null) Then
            Debug.WriteLine("Object data:");
            Debug.WriteLine(XmlDoc.xml);
        End If;
    End Sub OnBeforeCustomObjectSaveToPef;
End Class MyUpdateProgress;