IModelling.Splice

Syntax

Splice(Output: ITimeSeries;

Input: ITimeSeries;

Method: MsSpliceType;

[Direction: MsSpliceDirection = 0;]

[BoundByDates: Boolean = False;]

[StartDate: String = "";]

[EndDate: String = ""]): Variant;

Parameters

Output. Output variable.

Input. Variable that is spliced with the output one.

Method. Splice method.

Direction. Splice direction.

BoundByDates. Indicates whether series splice start and end dates are used.

StartDate. Series splice start date.

EndDate. Series splice end date.

Description

The Splice method splices variables.

Comments

Features of setting parameters:

Direction. Optional parameter for Fore. Default value: MsSpliceDirection.Both.
BoundByDates. Available values:

True. Series splice start and end dates are used to splice variables.
False. Series splice start and end dates are ignored.

Optional parameter for Fore. Default value: False.

StartDate, EndDate. Optional parameters for Fore. The default value is not set.

Example

Executing the example requires that the repository contains a modeling container with the MS identifier. This container includes a model with the MODEL_D identifier that is calculated by the determinate equation method and contains more than one input variable.

Add links to the Metabase and Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Inp_1, Inp_2: String;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Remember model calculation settings for points of the first input variable
    Inp_1 := TermInfo.TermInnerText;
    // Get the second input variable
    TransVar := Transf.Inputs.Item(1);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Remember model calculation settings for points of the second input variable
    Inp_2 := TermInfo.TermInnerText;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Splice(" + Inp_1 + ", " + Inp_2 + ", MsSpliceType.Butt, MsSpliceDirection.Both, True, " +
                            """" + "01.01.2003" + """" + "," + """" + "01.01.2006" + """" + ")";
    // Check expression correctness
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If expression is not correct, output message to console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example the model splices values of the first and second input variables.

Example of Use in Expressions

Expression 1:

Splice({Brazil|BCA},{China|BCA},MsSpliceType.Pch,MsSpliceDirection.Backward,False)

Result: values of Brazil|BCA and China|BCA factors are spliced by the splice method of data with rates of change in backward direction.

Use: it can be used in formulas of cross functional expression editor in any platform tool where it is available.

Expression 2:

Splice(X1,X2,MsSpliceType.Butt,MsSpliceDirection.Both,True,"01.01.2002","01.01.2007")

Result: values of X1 and X2 factors are spliced from 2002 to 2007.

Use: it can be used in model formulas of modeling container.