IModelling.Lead

Syntax

Lead(Input: ITimeSeries; [Value: Integer = 1]);

Parameters

Input. Variable.

Value. The parameter sets a shift (lag) of variable points in a time period.

Description

The Lead method shifts variable backwards by the specified number of points in a time period.

Comments

The Value parameter can take only positive values; optional parameter, the default value is 1, that is, shift by one point.

Example

Executing the example requires that the repository contains a modeling container with the MS identifier. This container includes a model with the MODEL_D identifier that is calculated by the determinate equation method and contains at least one input variable.

Add links to the Metabase and Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Lead(" + TermInfo.TermInnerText + ", 2)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If the expression is incorrect, display a message to the console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example the model will shift the first input variable by two points back in a time period.

Example of Use in Expressions

Expression 1:

Lead({Brazil|BCA},2)

Result: Brazil|BCA factor observations are moved by two points back in a time period.

Use: it can be used in formulas of cross functional expression editor in any platform tool where it is available.

Expression 2:

Lead(X1,3)

Result: X1 factor points are shifted by three points back in a time period.

Use: it can be used in model formulas of modeling container.