IModelling.Level

Syntax

Level(Input: ITimeSeries;

Method: MsLvlMethod;

[StartValue: Integer = 100]): Variant;

Parameters

Input. Variable.

Method. Transformation method.

StartValue. Initial value.

Description

The Level method applies the Level function to the specified variable.

Comments

The StartValue parameter is optional; the default value is 100.

Example

Executing the example requires that the repository contains a modeling container with the MS identifier. This container includes a model with the MODEL_D identifier that is calculated by the determinate equation method and contains at least one input variable.

Add links to the Metabase and Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Level(" + TermInfo.TermInnerText + ", MsLvlMethod.Diff, 200)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If the expression is incorrect, display a message to the console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example the model will transform the first input variable using the Level function.

Example of Use in Expressions

Expression 1:

Level({Brazil|BCA},MsLvlMethod.Log)

Result: the Brazil|BCA factor is transformed using the Level function.

Use: it can be used in formulas of cross functional expression editor in any platform tool where it is available.

Expression 2:

Level(X1,MsLvlMethod.PchA)

Result: the X1 factor is transformed using the Level function.

Use: it can be used in model formulas of modeling container.