IModelling.Hpf

Syntax

Hpf(Input: ITimeSeries;

Period: IMsPeriod;

[Lambda: Integer = 100]): Variant;

Parameters

Input. Smoothed variable.

Period. Period, at which the method is calculated

Lambda. Parameter is commanded by smoothness measure of variable.

Description

The Hpf method smoothes a variable using the Hodrick-Prescott filter (smoothing parameter is lambda).

Comments

Features of setting parameters:

Period. If the parameter is set to Null, the method is calculated at the entire time period
Lambda. Optional parameter. The default value is 100. The more is the parameter value, the more "smoothed" is the variable.

The Hodrick-Prescott filter (smoothing parameter is power) is implemented by the IModelling.HpfP method.

Example

Executing the example requires that the repository contains a modeling container with the MS identifier. This container includes a model with the MODEL_D identifier that is calculated by the determinate equation method and contains at least one input variable.

Add links to the Metabase and Ms system assemblies.

Sub UserHpf;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Hpf(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 120)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If the expression is incorrect, display a message to the console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserHpf;

After executing the example the model will smooth data of the first input variable with the Hodrick-Prescott filter at the period of 2000-2015.

Example of Use in Expressions

Expression 1:

Hpf({Chicago - population[t]}, Null, 130)

Result: data of the Chicago - population[t] time series is smoothed with the Hodrick-Prescott filter at the entire data period. Smoothing parameter equals to 130.

Use: it can be used in formulas of cross functional expression editor in any platform tool where it is available.

Expression 2:

Hpf(X1, setperiod("01.01.2000", "01.01.2015"))

Result: data of the X1 factor is smoothed with the Hodrick-Prescott filter at the specified data period.

Use: it can be used in model formulas of modeling container based on variables.