IInMemManager.GetMatrix

Copy example

Sub UserProc;
Var
    Mb: IMetabase;
    CubeInst: ICubeInstance;
    DestInst: ICubeInstanceDestination;
    InMem: IInMemManager;
    DimSS: IDimSelectionSet;
    DimS: IDimSelection;
    Matr: IMatrix;
Begin
    Mb := MetabaseClass.Active;
    // Open cube
    CubeInst := Mb.ItemById("STD_CUBE").Open(Null) As ICubeInstance;
    DestInst := CubeInst.Destinations.DefaultDestination;
    // Selection, according to which work is executed
    DimSS := DestInst.CreateDimSelectionSet;
    For Each DimS In DimSS Do
        If DimS.Dimension.Ident = "COUNTRY" Then
            DimS.SelectElement(0, False);
        Else
            DimS.SelectAll;
        End If;
    End For;
    // Manager for working with In-Memory cache
    InMem := New InMemManager.Create;
    // Check if cache contains data
    If InMem.CheckHasMatrix(DestInst) Then
        // Get matrix with data
        Matr := InMem.GetMatrix(DestInst.CreateExecutor, DimSS);
        // Get matrix
        ShowMatrix(Matr);
        // Update data in cache from source
        InMem.UpdateBySelection(DestInst, DimSS);
    Else
        InMem.PrepareMatrixPartial(DestInst, DimSS);
    End If;
End Sub UserProc;

Sub ShowMatrix(Matr: IMatrix);
Var
    Iter: IMatrixIterator;
Begin
    If Matr.Count <> 0 Then
        Iter := Matr.CreateIterator;
        Iter.Move(IteratorDirection.First);
        While Iter.Valid Do
            Debug.Write(Iter.Value + " ");
            Iter.Move(IteratorDirection.Next);
        End While;
        Debug.WriteLine("");
    Else
        Debug.WriteLine("Empty");
    End If;
End Sub ShowMatrix;