IModelling.R

Синтаксис Fore

R(Period: IMsPeriod;
Code: String;
Inputs: Array): Variant;

Синтаксис Fore.NET

R(Period: Prognoz.Platform.Interop.Ms.IMsPeriod;
  Code: string;
  Inputs: System.Array;
  Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Параметры

Period. Период, на котором рассчитывается метод. Если значение параметра Null, то метод рассчитывается на всём временном периоде;

Code. Выражение для расчета метода;

Inputs. Массив входных переменных;

Context. Контекст. Параметр используется только в Fore.NET.

Описание

Метод R выполняет преобразование данных с помощью методов пакета R.

Для использования данного метода в репозитории должна быть настроена интеграция с R. Подробнее о том, как можно настроить интеграцию вы можете узнать в разделе «Как настроить интеграцию с R?».

Особенности работы с параметром Code:

выражение задается на языке R. Более подробное описание языка R приведено в документации к R;
в выражении входные переменные обозначаются как X1, X2 и так далее, где 1, 2 - это индекс переменной в массиве Inputs. Индексация в массиве сплошная и начинается с единицы.

Пример Fore

Для выполнения примера предполагается наличие в репозитории контейнера моделирования с идентификатором «MS». В данном контейнере содержится модель с идентификатором «MODEL_D», рассчитываемая методом детерминированного уравнения и содержащая хотя бы одну входную переменную.

В репозитории должна быть настроена интеграция с R. Подробнее о том, как можно настроить интеграцию вы можете узнать в разделе «Как настроить интеграцию с R?».

Добавьте ссылки на системные сборки: Metabase, Ms.

Sub UserR;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := MetabaseClass.Active;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById("MS").Bind;
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms;Stat";
    // Задаем выражение расчета модели
    Expr.AsString := "R(SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + ")," +
        """" + "Y <- X1 + 1;" + """" + "," + TermInfo.TermInnerText + ") ";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save;
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub UserR;

В результате выполнения примера модель детерминированного уравнения будет рассчитано с помощью R.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Ms;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := Params.Metabase;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms;Stat";
    // Задаем выражение расчета модели
    Expr.AsString := "R(SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + ")," +
        """" + "Y <- X1 + 1;" + """" + "," + TermInfo.TermInnerText + ") ";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save();
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else System.Diagnostics.Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub;

Пример использования в выражениях

Выражение 1:

r(setperiod("01.01.2000", "01.01.2015"), "Y <- X1 + 1;", {Чикаго - население[t]})

Результат: значения временного ряда «Чикаго - население» будут увеличены на единицу с помощью методов пакета R.

Применение: можно использовать в формулах вычисляемых рядов базы данных временных рядов и в формулах моделей, основанных на атрибутах.

Выражение 2:

R(SetPeriod("01.01.2000", "01.01.2015"), "Y <- X1 + 1;", X1, X2)

Результат: значение переменной X1 будет увеличено на единицу с помощью методов пакета R.

Применение: можно использовать в формулах моделей контейнера моделирования.

См. также:

IModelling | База данных временных рядов: методы R | Контейнер моделирования: модель «R»