IMetabaseSecuritySubjectUpdateSetup.RenameInDBMS

Копировать пример

Sub UserProc;
Var
    MB: IMetabase;
    MS: IMetabaseSecurity;
    Policy: IMetabasePolicy;
    Session: ILogonSession;
    User: IMetabaseUser;
    UsUpdate: IMetabaseUsersUpdate;
    UsUpdateSec: IMetabaseSecuritySubjectUpdateSetup;
    Lic: Object;
    UserName: String;
Begin
    MB := MetabaseClass.Active;
    // Получим информацию о текущей сессии с репозиторием
    Session := MB.LogonSession;
    // Укажем учётные данные текущего пользователя, если он обладает правами администратора на уровне СУБД
    Session.Credentials("$SYSTEM", True) := Session.LogonCredentials;
    // Получим лицензию для возможности работы с менеджером безопасности
    Lic := MB.RequestLicense(UiLicenseFeatureType.Adm);
    MS := MB.Security;
    // Создадим объект обновления пользователей
    UsUpdate := MS.CreateUsersUpdate;
    // Получим доменного пользователя, для которого необходимо выполнить синхронизацию с LDAP
    UserName := "DOMAIN\USER";
    User := MS.ResolveName(UserName) As IMetabaseUser;
    If User <> Null Then
        If User.IsNT And User.External = False Then
            // Выведем атрибуты доменного пользователя до синхронизации
            Debug.WriteLine("Атрибуты доменного пользователя до синхронизации с LDAP:");
            Debug.WriteLine("Name " + User.Name + ":");
            Debug.WriteLine("SID: " + User.Sid.AsString);
            Debug.WriteLine("UPN: " + User.UserPrincipalName);
            Debug.WriteLine("Description: " + User.Description);
            Debug.WriteLine("");
            // Добавим доменного пользователя в обновление
            UsUpdate.Add(User);
            // Установим способ обновления - синхронизация атрибутов с LDAP
            UsUpdateSec := UsUpdate.ItemSetup(0);
            UsUpdateSec.UpdateType := MetabaseSecuritySubjectUpdateType.LDAPSync;
            // Переименуем доменного пользователя на уровне СУБД, если не используется встроенная авторизация
            Policy := MS.Policy;
            If Policy.CheckUserPassword = False Then
                UsUpdateSec.RenameInDBMS := True;
            End If;
            // Обновим информацию о доменном пользователе и выполним синхронизацию атрибутов
            MS.UpdateUsers(UsUpdate);
            // Выведем атрибуты доменного пользователя после синхронизации
            Debug.WriteLine("Атрибуты доменного пользователя после синхронизации с LDAP:");
            Debug.WriteLine("Name: " + User.Name);
            Debug.WriteLine("SID: " + User.Sid.AsString);
            Debug.WriteLine("UPN: " + User.UserPrincipalName);
            Debug.WriteLine("Description: " + User.Description);
            Debug.WriteLine("");
            // Сохраним изменения
            MS.Apply;
        End If;
    Else
        Debug.WriteLine("Пользователь " + UserName + " не найден в менеджере безопасности");
    End If;
    // Освободим лицензию
    Lic := Null;
End Sub UserProc;