IMsCalculationChainGroup.LevelParam

Копировать пример

Sub UserProc;
Var
    mb: IMetabase;
    MsKey: Integer;
    Metamodel: IMsMetaModel;
    Params: IMsModelParams;
    Param: IMsModelParam;
    Chain: IMsCalculationChainEntries;
    i: Integer;
    ChainEntry: IMsCalculationChainEntry;
    Group: IMsCalculationChainGroup;
    OutputPeriod: IMsDatePeriod;
Begin
    // Получаем текущий репозиторий
    mb := MetabaseClass.Active;
    // Получаем ключ контейнера моделирования
    MsKey := mb.GetObjectKeyById("MS");
    // Получаем метамодель
    Metamodel := mb.ItemByIdNamespace("META_LEVELPARAM", MsKey).Edit As IMsMetaModel;
    // Получаем коллекцию параметров метамодели
    Params := Metamodel.Params;
    // Очищаем коллекцию параметров метамодели
    Params.Clear;
    // Добавляем новый параметр
    Param := Params.Add;
    // Указываем тип параметра - динамика
    Param.ParamType := TsParamType.Frequency;
    // Указываем значение по умолчанию - годовая динамика
    Param.DefaultValue := DimCalendarLevelSet.Year;
    // Задаем наименование и идентификатор параметра
    Param.Name := "Динамика расчета";
    Param.Id := "Formula_Level";
    // Получаем цепочку расчета
    Chain := Metamodel.CalculationChain;
    // Перебираем элементы цепочки до тех пор, пока не найдём папку
    For i := 0 To Chain.Count - 1 Do
        ChainEntry := Chain.Item(i);
        If ChainEntry.Type = MsCalculationChainEntryType.Folder Then
            Group := ChainEntry As IMsCalculationChainGroup;
            Break;
        End If;
    End For;
    // Указываем, что динамика расчета элементов в папке определяется параметром
    Group.LevelParam := "Formula_Level";
    // Задаем период выгрузки данных для элементов в папке
    OutputPeriod := Group.OutputPeriod As IMsDatePeriod;
    OutputPeriod.Start := DateTime.Parse("01.01.2016");
    OutputPeriod.End_ := DateTime.Parse("01.01.2020");
    // Сохраняем изменения в метамодели
    (Metamodel As IMetabaseObject).Save;
End Sub UserProc;