IDtOleDbConsumer.ConnectionString

Копировать пример

Sub UserProc;
Var
    MB: IMetabase;
    MObj: IMetabaseObject;
    EtlTask: IEtlTask;
    EtlConsumer: IEtlPlainDataConsumer;
    OleDbConsumer: IDtOleDbConsumer;
    WxConsumer: IWxRectangle;
    WxETLConsumer: IWxETLObject;
Begin
    MB := MetabaseClass.Active;
    // Поиск задачи ETL. Объект репозитория с идентификатором "ETL"
    MObj := MB.ItemById("ETL").Edit;
    EtlTask := MObj As IEtlTask;
    // Начало создания приёмника
    // Создание объекта "Экспорт в OleDb"
    EtlConsumer := EtlTask.Create(EtlObjectType.PlainDataOleDbConsumer) As IEtlPlainDataConsumer;
    EtlConsumer := EtlConsumer.Edit;
    EtlConsumer.Id := "OleDb_Consumer";
    EtlConsumer.Name := "Экспорт в OleDb";
    EtlConsumer.Description := "Экспорт в OleDb";
    // Настройка приёмника данных
    OleDbConsumer := EtlConsumer.Consumer As IDtOleDbConsumer;
    OleDbConsumer.ConnectionString := "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\db.mdb;Persist Security Info=False";
    OleDbConsumer.Table := "Table_1";
    EtlConsumer.FillDefault;
    // Сохраняем приёмник
    EtlConsumer.Save;
    // Конец создания приёмника
    // Начало создания визуального объекта
    WxConsumer := EtlTask.Workspace.CreateRectangle;
    WxETLConsumer := New WxETLObject.Create;
    WxETLConsumer.ETLObject := EtlConsumer;
    WxConsumer.Style.TextPosition := WxTextPosition.Bottom;
    WxConsumer.Style.PictureMarginTop := -10;
    WxConsumer.PinPosition := New GxPointF.Create(50, 50);
    WxConsumer.Extension := WxETLConsumer As IWxShapeExtension;
    // Конец создания визуального объекта
    // Сохранение задачи ETL
    MObj.Save;
End Sub UserProc;