Calculating System of Non-Linear Equations

Copy example

Sub UserProc;
Var
    Eqs: ISmNonLinearEquations;
    Funcs: Array[3] Of String;
    inits: Array[3] Of Double;
    d: Double;
    i, res: Integer;
Begin
    Eqs := New SmNonLinearEquations.Create As ISmNonLinearEquations;
    // Set equations
    funcs[0] := "X1-(1-0.2*X2-0.1*X3)";
    funcs[1] := "X2-(1.2-0.1*X1-0.2*X3)";
    funcs[2] := "X3-(0.8-0.1*X1-0.1*X2)";
    Eqs.Functions := Funcs;
    // Set initial approximations
    inits[0] := -1000;
    inits[1] := 120000;
    inits[2] := 0.8;
    Eqs.InitApproximation := inits;
    // Set coefficient order
    Eqs.CoefficientsOrder := "X1;X2;X3";
    // Set maximum number of iterations, in which solution should be found
    Eqs.MaxIteration := 1000;
    // Set accuracy of solution
    Eqs.Tolerance := 0.00000000001;
    // Set system calculation method
    Eqs.MethodType := NonLinearEquationsType.IterationsMethod;
    // Execute calculation
    res := Eqs.Execute;
    Debug.WriteLine(Eqs.Errors);
    // Output results
    If (res = 0) Then
        For i := 0 To (Eqs.Solution.Length - 1) Do
            d := Eqs.Solution[i];
            Debug.WriteLine("Value X" + (i + 1).ToString + ": " + d.ToString);
        End For;
        Debug.WriteLine("Values of functions:");
        For i := 0 To Eqs.FunctionValues.Length - 1 Do
            d := Eqs.FunctionValues[i];
            Debug.WriteLine(Eqs.Functions[i] + " = " + d.ToString);
        End For;
    End If;
End Sub UserProc;