IDmHighlightExceptions.Threshold

Syntax

Threshold: Double;

Description

The Threshold property determines the threshold value for detection of exceptions.

Comments

Available value range: (0;1].

Threshold value is the maximum share of exceptions contained in data.

Example

Executing the example requires that the repository contains:

A table with the DM_TABLE identifier containing data for analysis
A regular report with the DM_REPORT_RES identifier, to which analysis results will be loaded.

Add links to the Metabase, Ms, Report, Stat, Tab system assemblies.

Sub UserHiEx;
Var
    mb: IMetabase;
    ReportDS: IDmReportDataSource;
    TableDS: IDmTableDataSource;
    Method: IDmMethod;
    Report: IPrxReport;
    Shs: IPrxSheets;
    Sheet: ITabSheet;
    DM: IDmHighlightExceptions;
    i: Integer;
    Attrs: Array Of Integer;
    Reports: IDmReports;
    DmReport: IDmReport;
Begin
    mb := MetabaseClass.Active;
    // Create calculation method
    Method := (New DataMiningMethod.Create) As IDmMethod;
    // Specify method type
    Method.Kind := DmMethodKind.HighlightExceptions;
    // Create table data source
    TableDS := (New TableDataSource.Create) As IDmTableDataSource;
    // Determine source table
    TableDS.Table := mb.ItemByID("DM_TABLE").Bind;
    // Set input data source
    Method.InputDataSource := TableDS;
    // Create a data source that is a regular report
    ReportDS := (New ReportDataSource.Create) As IDmReportDataSource;
    // Set data consumer
    Method.OutputDataSource := ReportDS;
    // Set up calculation method parameters
    DM := Method.Details As IDmHighlightExceptions;
    // Set factors to search exceptions
    Attrs := New Integer[TableDS.FieldCount];
    For i := 0 To Attrs.Length - 1 Do
        Attrs[i] := i;
    End For;
    DM.Attributes := Attrs;
    // Set threshold
    DM.Threshold := 0.57;
    // Perform analysis and output results
    Reports := Method.Execute;
    DmReport := reports.FindByType(DmReportType.HighlightExceptions);
    ReportDS := DmReport.Generate;
    ReportDS.TabSheet.View.Selection.SelectAll;
    ReportDS.TabSheet.View.Selection.Copy;
    // Get regular report, to which results will be loaded
    Report := mb.ItemByID("DM_REPORT_RES").Edit As IPrxReport;
    Shs := Report.Sheets;
    Shs.Clear;
    Sheet := (Shs.Add("", PrxSheetType.Table) As IPrxTable).TabSheet;
    Sheet.Table.Paste;
    Sheet.Columns(0, 1).AdjustWidth;
    Sheet.Rows(0, 1).AdjustHeight;
    Report.Sheets.Item(0).Name := ReportDS.Caption;
    // Save loaded data
    (Report As IMetabaseObject).Save;
End Sub UserHiEx;

After executing the example the Exception Search method performs data mining for data from the DM_TABLE table. Analysis results will be loaded to the DM_REPORT_RES report.