IEtlPlainDataCopy.RemoveLink

Copy example

Sub UserProc;
Var
    Mb: IMetabase;
    Task: IEtlTask;
    CopyObj: IEtlPlainDataCopy;
    FProvider: IDtTextProvider;
    Tab: IDatasetModel;
    FConsumer: IDtMetabaseConsumer;
    ProvFields, ConsFields: IDtFieldDefinitions;
    i: Integer;
    WxConsumer: IWxRectangle;
    WxETLConsumer: IWxEtlObject;
Begin
    Mb := MetabaseClass.Active;
    Task := MB.ItemById("OBJ_ETL").Edit As IEtlTask;
    // Create an object that copies data
    CopyObj := Task.Create(EtlObjectType.PlainDataCopy) As IEtlPlainDataCopy;
    CopyObj := CopyObj.Edit;
    // Set up data source parameters
    FProvider := New DtTextProvider.Create As IDtTextProvider;
    FProvider.File := "C:\ETL_imp.txt";
    FProvider.DelimitedColumnDelimiter := ",";
    FProvider.HeaderRow := 1;
    FProvider.FormatType := DtTextFormatType.Delimited;
    FProvider.RangeHasHeader := True;
    FProvider.RangeFirstRow := 1;
    COpyObj.Provider := FProvider;
    // Set up data consumer parameters
    FConsumer := New DtMetabaseConsumer.Create;
    Tab := MB.ItemById("OBJ_TBL").Edit As IDatasetModel;
    FConsumer.Dataset := Tab;
    CopyObj.Consumer := FConsumer;
    // Link source and consumer data
    ProvFields := FProvider.Fields;
    ConsFields := FConsumer.Fields;
    CopyObj.AutoLink;
    For i := 0 To ProvFields.Count - 1 Do
        If Not CopyObj.IsLinked(ProvFields.Item(i).Name, ConsFields.Item(i).Name) Then
            CopyObj.AddLink(ProvFields.Item(i).Name, ConsFields.Item(i).Name);
        End If;
    End For;
    //Unbind by the "OWNER" field
    CopyObj.RemoveLink("OWNER", "OWNER");
    // Clear data consumer
    CopyObj.ClearConsumer := True;
    //Handle errors
    CopyObj.ActionOnProblem := EtlActionOnProblem.DiscardRecordsInTransaction;
    CopyObj.CommitCount := 10;
    // Save the object that copies data
    CopyObj.Save;
    //Start of visual object creation
    WxConsumer := Task.Workspace.CreateRectangle;
    WxETLConsumer := New WxEtlObject.Create;
    WxETLConsumer.EtlObject := CopyObj;
    WxConsumer.Style.TextPosition := WxTextPosition.Bottom;
    WxConsumer.Style.PictureMarginTop := -10;
    WxConsumer.PinPosition := New GxPointF.Create(50, 50);
    WxConsumer.Extension := WxETLConsumer As IWxShapeExtension;
    //End of visual object creation
    //Execute task
    Task.Execute(Null);
    //Save ETL task object
    (Task As IMetabaseObject).Save;
End Sub UserProc;