IModelling.MedianSmooth

Синтаксис Fore

MedianSmooth(Input: ITimeSeries;
Period: IMsPeriod;
[WindowSize: Integer = 5];

[Casewise: MsCasewise = 0]): Variant;

Синтаксис Fore.NET

MedianSmooth(Input: Prognoz.Platform.Interop.Ms.ITimeSeries;
Period: Prognoz.Platform.Interop.Ms.IMsPeriod;
WindowSize: integer;

Casewise: Prognoz.Platform.Interop.Ms.MsCasewise;
Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Параметры

Input. Моделируемая переменная;

Period. Период, на котором рассчитывается метод. Если значение параметра Null, то метод рассчитывается на всём временном периоде;

WindowSize. Размер окна;

Casewise. Метод обработки пропусков;

Context. Контекст. Параметр используется только в Fore.NET.

Описание

Метод MedianSmooth осуществляет моделирование переменной с помощью медианного сглаживания.

Пример Fore

Для выполнения примера предполагается наличие в репозитории контейнера моделирования с идентификатором «MS». В данном контейнере содержится модель с идентификатором «MODEL_D», рассчитываемая методом детерминированного уравнения и содержащая хотя бы одну входную переменную.

Добавьте ссылки на системные сборки: Metabase, Ms.

Sub ProcMedianSmooth;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    Mb := MetabaseClass.Active;
    ModelSpace := Mb.ItemById("MS").Bind;
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.Pointwise;
    Expr := Determ.Expression;
    Expr.References := "Ms";
    Expr.AsString := "MedianSmooth(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 5, MsCasewise.Yes)";
    If Expr.Valid
        Then ModelObj.Save;
        Else Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub ProcMedianSmooth;

После выполнения примера модель будет осуществлять преобразование первой входной переменной методом медианного сглаживания на периоде с 2000 по 2015 год. Расчёт выполняется с применением обработки пропусков методом Casewise.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    Mb := Params.Metabase;
    ModelSpace := Mb.ItemById["MS"].Bind();
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    Expr := Determ.Expression;
    Expr.References := "Ms";
    Expr.AsString := "MedianSmooth(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 5, MsCasewise.Yes)";
    If Expr.Valid
        Then ModelObj.Save();
        Else System.Diagnostics.Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub;

Пример использования в выражениях

Выражение 1:

MedianSmooth({Brazil|BCA}, SetPeriod("01.01.2000", "01.01.2015"), 5, MsCasewise.Yes)

Результат: для показателя Brazil|BCA будет применено медианное сглаживание (размер окна равняется пяти), расчёт выполняется на периоде с 2000 по 2015 год с применением обработки пропусков методом Casewise.

Применение: можно использовать в формулах вычисляемых рядов базы данных временных рядов и в формулах моделей контейнера моделирования, являющегося дочерним по отношению к базе данных временных рядов.

Выражение 2:

MedianSmooth(X1, SetPeriod("01.01.2000", "01.01.2015"), 7, MsCasewise.Yes)

Результат: для фактора X1 будет применено медианное сглаживание (размер окна равняется семи), расчёт выполняется на периоде с 2000 по 2015 год с применением обработки пропусков методом Casewise.

Применение: можно использовать в формулах моделей контейнера моделирования.

См. также:

IModelling | Метод расчёта медианного сглаживания | База данных временных рядов: калькулятор | Контейнер моделирования: редактирование регрессора/формулы