IModelling.DateSeries

Синтаксис

DateSeries([OutputFrequency: MsFrequency = 0]): Variant;

DateSeries(OutputFrequency: Prognoz.Platform.Interop.Ms.MsFrequency, Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Параметры

OutputFrequency. Календарная динамика результирующего ряда. По умолчанию параметр равен динамике расчёта. Например, если задан период расчёта с 2015 по 2020 год и метод используется в виде «DateSeries(MsFrequency.Monthly)», то будут получены все месяцы заданного периода расчёта;

Примечание. Если параметр не задан, то результирующий ряд создаётся с динамикой текущего расчёта.

Context. Контекст. Параметр используется только в Fore.NET.

Описание

Метод DateSeries возвращает текущее значение даты для каждой точки ряда в зависимости от заданных периодов расчёта.

Комментарии

Используется при расчёте детерминированного уравнения:

Пример

Для выполнения примера предполагается наличие в репозитории контейнера моделирования с идентификатором MS, который содержит модель с идентификатором MODEL_D. Модель рассчитывается методом детерминированного уравнения и содержит хотя бы одну входную переменную.

Добавьте ссылки на системные сборки: Metabase, Ms, ForeSystem (для примера на Fore.NET).

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := MetabaseClass.Active;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById("MS").Bind;
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Получаем параметры расчёта модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчёт
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Получаем выражение расчёта модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчёта модели
    Expr.AsString := "iif(DateSeries(MsFrequency.Annual)>=DateTime.Parse(""01.01.2018"")," + TermInfo.TermInnerText + ",0)";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение корректное, то сохраняем модель
        Then ModelObj.Save;
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub UserProc;

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := Params.Metabase;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Получаем параметры расчёта модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчёт
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Получаем выражение расчёта модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчёта модели
    Expr.AsString := "iif(DateSeries(MsFrequency.Annual)>=DateTime.Parse(""01.01.2018"")," + TermInfo.TermInnerText + ",0)";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение корректное, то сохраняем модель
        Then ModelObj.Save();
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else System.Diagnostics.Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub;

В результате выполнения примера для модели будет изменена формула:

В консоль будет выведено сообщение об ошибке в формуле, если выражение некорректно.

Пример использования в выражениях

Выражение 1:

iif(DateSeries >= DateTime.Parse("01.01.2018"), {Brazil|BCA}, Null)

Результат: для значений от 2018 года выражение будет возвращать наблюдение показателя Brazil|BCA.

Применение: можно использовать в формулах вычисляемых рядов базы данных временных рядов и в формулах моделей контейнера моделирования, основанных на атрибутах.

Выражение 2:

iif(DateSeries = DateTime.Parse("01.01.2018"), X1, Null)

Результат: для значений 2018 года выражение будет возвращать значения фактора X1.

Применение: можно использовать в формулах моделей контейнера моделирования, основанных на переменных.

См. также:

IModelling