IModelling.Combine

Синтаксис Fore

Combine(Forecast: IMsForecast; Period: IMsPeriod): Variant;

Синтаксис Fore.NET

Combine(Forecast: Prognoz.Platform.Interop.Ms.IMsForecast; Period: Prognoz.Platform.Interop.Ms.IMsPeriod): object;

Параметры

Forecast. Прогнозный ряд;

Period. Период прогнозирования данных.

Описание

Метод Combine возвращает ряд, содержащий данные исходного ряда на период идентификации и прогнозного ряда на период прогнозирования.

Комментарии

Если периоды идентификации и прогнозирования пересекаются, то приоритетнее будут прогнозные данные. Таким образом, возвращаемый ряд будет содержать усеченные данные на период идентификации и полные данные на период прогнозирования.

Пример Fore

Для выполнения примера в репозитории предполагается наличие контейнера моделирования с идентификатором «MS». В данном контейнере содержится модель с идентификатором «MODEL_D», рассчитываемая методом детерминированного уравнения и содержащая хотя бы одну входную переменную.

Добавьте ссылки на системные сборки: Metabase, Ms.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := MetabaseClass.Active;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById("MS").Bind;
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчета модели
    Expr.AsString := "Combine(Arima(" + TermInfo.TermInnerText +
        ", Default_, """ + "" + """, """ + "1" + """, 0, Estimate), SetPeriod(" +
        """" + "01.01.2010" + """" + "," + """" + "01.01.2015" + """" +
        "))";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save;
        // Если выражение некорректное, то выводим сообщение в окно консоли 
        Else Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub UserProc;

В результате выполнения примера модель будет возвращать ряд, содержащий данные исходного ряда на период идентификации и прогнозного ряда на заданный период прогнозирования для метода «ARIMA».

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Ms;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := Params.Metabase;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчета модели
    Expr.AsString := "Combine(Arima(" + TermInfo.TermInnerText +
        ", Default_, """ + "" + """, """ + "1" + """, 0, Estimate), SetPeriod(" +
        """" + "01.01.2010" + """" + "," + """" + "01.01.2015" + """" +
        "))";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save();
        // Если выражение некорректное, то выводим сообщение в окно консоли 
        Else System.Diagnostics.Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub;

Пример использования в выражениях

Выражение 1:

Combine(Arima({ВВП|Анкоридж[t]}, Default_, "", "1", 0, Estimate), SetPeriod("01.01.2010", "01.01.2015"))

Результат: для модели «ARIMA» будет получен ряд, содержащий данные исходного ряда на период идентификации и прогнозного ряда на заданный период прогнозирования.

Выражение 2:

Combine(Arima(X1, Default_, "", "1", 0, Estimate), SetPeriod("01.01.2010", "01.01.2015"))

Результат: для модели «ARIMA» будет получен ряд, содержащий данные исходного ряда на период идентификации и прогнозного ряда на заданный период прогнозирования.

См. также:

IModelling