IModelling.MovAvgR

Синтаксис Fore

MovAvgR(Input: ITimeSeries;
       Period: IMsPeriod;
       [WindowSize: Integer = 5;]
       [Casewise: MsCasewise = 0]): Variant;

Синтаксис Fore.NET

MovAvgR(Input: Prognoz.Platform.Interop.Ms.ITimeSeries;
        Period: Prognoz.Platform.Interop.Ms.IMsPeriod;
        WindowSize: integer;
        Casewise: Prognoz.Platform.Interop.Ms.MsCasewise;
        Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Параметры

Input. Моделируемая переменная.

Period. Период, на котором рассчитывается метод. Если значение параметра Null, то метод рассчитывается на всём временном периоде;

WindowSize. Размер окна;

Casewise. Метод обработки пропусков;

Context. Контекст. Параметр используется только в Fore.NET.

Описание

Метод MovAvgR преобразует данные переменной методом скользящего среднего с помощью пакета R.

Для использования данного метода в репозитории должна быть настроена интеграция с R. Подробнее о том, как можно настроить интеграцию вы можете узнать в разделе «Как настроить интеграцию с R?».

Пример Fore

Для выполнения примера предполагается наличие в репозитории контейнера моделирования с идентификатором «MS». В данном контейнере содержится модель с идентификатором «MODEL_D», рассчитываемая методом детерминированного уравнения и содержащая хотя бы одну входную переменную.

В репозитории должна быть настроена интеграция с R. Подробнее о том, как можно настроить интеграцию вы можете узнать в разделе «Как настроить интеграцию с R?».

Добавьте ссылки на системные сборки: Metabase, Ms.

Sub ProcAvgR;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := MetabaseClass.Active;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById("MS").Bind;
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчета модели
    Expr.AsString := "MovAvgR(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 3, MsCasewise.Yes)";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save;
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub ProcAvgR;

После выполнения примера модель будет осуществлять преобразование первой входной переменной методом скользящего среднего на периоде с 2000 по 2015 год. Используется метод обработки пропусков методом Casewise. Расчет выполняется с помощью пакета R.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Получаем репозиторий
    Mb := Params.Metabase;
    // Получаем контейнер моделирования
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Получаем модель
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Получаем параметры расчета модели
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Получаем первую входную переменную
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Задаем режим передачи переменной в расчет
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Получаем выражение расчета модели
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Задаем выражение расчета модели
    Expr.AsString := "MovAvgR(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 3, MsCasewise.Yes)";
    // Проверяем корректность выражения
    If Expr.Valid
        // Если выражение задано корректно, то сохраняем модель
        Then ModelObj.Save();
        // Если выражение некорректное, то выводим сообщение в окно консоли
        Else System.Diagnostics.Debug.WriteLine("Модель не сохранена: ошибка в формуле");
    End If;
End Sub;

Пример использования в выражениях

Выражение 1:

MovAvgR({Чикаго - население[t]}, SetPeriod("01.01.2000", "01.01.2015"), 4, MsCasewise.Yes)

Результат: для временного ряда «Чикаго - население» будет применен метод скользящего среднего с окном равным четырем на периоде с 2000 по 2015 год. Применяется обработка пропусков методом Casewise. Расчет выполняется с помощью пакета R.

Применение: можно использовать в формулах вычисляемых рядов базы данных временных рядов и в формулах моделей контейнера моделирования, являющегося дочерним по отношению к базе данных временных рядов, расчёт ведется без учета пропущенных значений.

Выражение 2:

MovAvgR(X1, SetPeriod("01.01.1990", "01.01.2015"))

Результат: для фактора «X1» будет применен метод скользящего среднего с помощью пакета R на периоде с 1990 по 2015 год.

Применение: можно использовать в формулах моделей контейнера моделирования.

См. также:

IModelling | Метод расчёта скользящего среднего | База данных временных рядов: калькулятор | Контейнер моделирования: редактирование регрессора/формулы