IEaxGridHeaderSettings.Behaviour

Синтаксис Fore

Behaviour: EaxGridHeaderBehaviour;

Синтаксис Fore.NET

Behaviour: Prognoz.Platform.Interop.Express.EaxGridHeaderBehaviour;

Описание

Свойство Behaviour определяет поведение строк и столбцов при вставке области данных.

Комментарии

Свойство актуально только для области данных регламентного отчета.

Пример Fore

Для выполнения примера предполагается наличие регламентного отчета с идентификатором «REPORT». Отчет содержит область данных, для которой настроена раскрывающаяся иерархия.

Добавьте ссылки на системные сборки: Express, Metabase, Pivot, Report, Tab.

Sub UserProc;
Var
    mb: IMetabase;
    Report: IPrxReport;
    Table: ITabSheet;
    DataArea: IEaxDataAreaViews;
    Grid: IEaxGrid;
    Slice: IEaxDataAreaPivotSlice;
    SettBase: IDataAreaHeaderSettingsBase;
    ViewSett: IEaxGridViewSettings;
    sett: IEaxGridHeaderSettings;
Begin
    mb := MetabaseClass.Active;
    Report :=  MB.ItemById("REPORT").Edit As IPrxReport;
    Table := (Report.ActiveSheet As IPrxTable).TabSheet;
    DataArea := Report.DataArea.Views;
    Grid := DataArea.FindById("EaxObject") As IEaxGrid;
    Slice := Grid.Slice As IEaxDataAreaPivotSlice;
    SettBase := Slice.Pivot.LeftHeader As IDataAreaHeaderSettingsBase;
    ViewSett := Grid.ViewSettings;
    sett := ViewSett.GetViewSettings(SettBase) As IEaxGridHeaderSettings;
    // Поведение строк/столбцов
    sett.Behaviour := EaxGridHeaderBehaviour.Fixed;
    // Видимость пиктограмм сортировки
    sett.DisplaySortIcons := True;
    // Отступ в раскрывающейся иерархии
    sett.HierarchyIndent := 15;
    (Report As IMetabaseObject).Save;
End Sub UserProc;

После выполнения примера для боковика области данных регламентного отчета будут заданы следующие настройки:

• используется фиксированный размер строк и столбцов;

• пиктограммы сортировки видимые;

• задан отступ в раскрывающейся иерархии.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Report;
Imports Prognoz.Platform.Interop.Tab;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Pivot;
…
Public Shared Sub Main(Params: StartParams);
Var
    mb: IMetabase;
    Report: IPrxReport;
    Table: ITabSheet;
    DataArea: IEaxDataAreaViews;
    Grid: IEaxGrid;
    Slice: IEaxDataAreaPivotSlice;
    SettBase: IDataAreaHeaderSettingsBase;
    ViewSett: IEaxGridViewSettings;
    sett: IEaxGridHeaderSettings;
Begin
    mb := Params.Metabase;
    Report :=  MB.ItemById["REPORT"].Edit() As IPrxReport;
    Table := (Report.ActiveSheet As IPrxTable).TabSheet;
    DataArea := Report.DataArea.Views;
    Grid := DataArea.FindById("EaxObject") As IEaxGrid;
    Slice := Grid.Slice As IEaxDataAreaPivotSlice;
    SettBase := Slice.Pivot.LeftHeader As IDataAreaHeaderSettingsBase;
    ViewSett := Grid.ViewSettings;
    sett := ViewSett.GetViewSettings[SettBase] As IEaxGridHeaderSettings;
    // Поведение строк/столбцов
    sett.Behaviour := EaxGridHeaderBehaviour.eghbFixed;
    // Видимость пиктограмм сортировки
    sett.DisplaySortIcons := True;
    // Отступ в раскрывающейся иерархии
    sett.HierarchyIndent := 15;
    (Report As IMetabaseObject).Save();
End Sub;

См. также:

IEaxGridHeaderSettings