IEaxAnalyzerCore.BubbleChart

Fore Syntax

Fore.NET Syntax

BubbleChart: Prognoz.Platform.Interop.Express.IEaxBubbleChart;

Description

The BubbleChart property returns the object containing express report bubble chart.

Comments

A bubble chart provides a possibility to view indicators change as an animated chart. The chart series are represented as bubbles, which motion shows the change of series values.

Fore Example

Executing the example requires an express report with the EXPRESS_REPORT identifier. Dimensions of the express report data source are based on the following dictionaries:

The dictionary with the D_Indicators identifier containing four elements. Data stored by these elements will determine the motion of bubble chart bubbles.
The territory dictionary with the D_Map identifier.
The calendar dictionary with the Calendar identifier.

Sub UserProc;
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, ODim, TimeDim: IDimSelection;
    Bubble: IEaxBubbleChart;
Begin
    MB := MetabaseClass.Active;
    Eax := MB.ItemById("EXPRESS_REPORT").Edit As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Search for dimensions
    IDim := Selection.FindById("D_Indicators");
    ODim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Reset dimensions positions
    Pivot.LeftHeader.Clear;
    Pivot.TopHeader.Clear;
    //Select the first territory
    ODim.SelectElement(0, False);
    //Select elements of the first calendar level
    TimeDim.SelectSiblings(0);
    //Set up bubble chart parameters
    //Determine changes
    Bubble := Eax.BubbleChart;
    //Activate bubble chart
    Bubble.Active := True;
    //Set up dimensions
    Bubble.IndicatorsDim := IDim.Dimension;
    Bubble.ObjectivesDim := ODim.Dimension;
    Bubble.TimeLineDim := TimeDim.Dimension;
    //Determine elements used for value selection for bubble chart dimensions
    Bubble.IndicatorElement(BubbleChartDimension.X) := 0;
    Bubble.IndicatorElement(BubbleChartDimension.Y) := 1;
    Bubble.IndicatorElement(BubbleChartDimension.Radial) := 2;
    Bubble.IndicatorElement(BubbleChartDimension.Color) := 3;
    //Save changes
    (Eax As IMetabaseObject).Save;
End Sub UserProc;

After executing the example express report for bubble chart is set up. The required location of dimensions is specified in express report and the required selection is specified by dimensions. Dimensions are specified and elements are determined for the bubble chart, which values are used to form the bubbles motion dynamic.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.Chart;
Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Pivot;

Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, ODim, TimeDim: IDimSelection;
    Bubble: IEaxBubbleChart;
Begin
    MB := Params.Metabase;
    Eax := MB.ItemById["EXPRESS_REPORT"].Edit() As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Dimensions search
    IDim := Selection.FindById("D_Indicators");
    ODim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Reset dimensions positions
    Pivot.LeftHeader.Clear();
    Pivot.TopHeader.Clear();
    //Select the first territory
    ODim.SelectElement(0, False);
    //Select elements of the first calendar level
    TimeDim.SelectSiblings(0);
    //Set up bubble chart parameters
    //Determine changes
    Bubble := Eax.BubbleChart;
    //Activate bubble chart
    Bubble.Active := True;
    //Set up dimensions
    Bubble.IndicatorsDim := IDim.Dimension;
    Bubble.ObjectivesDim := ODim.Dimension;
    Bubble.TimeLineDim := TimeDim.Dimension;
    //Determine elements used for value selection for bubble chart dimensions
    Bubble.IndicatorElement[BubbleChartDimension.bcdX] := 0;
    Bubble.IndicatorElement[BubbleChartDimension.bcdY] := 1;
    Bubble.IndicatorElement[BubbleChartDimension.bcdRadial] := 2;
    Bubble.IndicatorElement[BubbleChartDimension.bcdColor] := 3;
    //Save changes
    (Eax As IMetabaseObject).Save();
End Sub;