Работа с библиотекой pplib++

Библиотека pplib++ предназначена для работы с экспресс-отчетами, аналитическими панелями, базами данных временных рядов мобильного приложения, а также для представления источников данных, их измерений, таблиц и работы с репозиторием.

Функциональные возможности

Основные функциональные возможности библиотеки:

Особенности использования

В библиотеке pplib++ помимо классов используются их обёртки с умным указателем, который удаляет объекты, когда они не нужны. Для обозначения обёрток перед названием класса указывается символ «S», например для класса PPLDimension существует обёртка SPPLDimension.

Подключение библиотеки

Для подключения библиотеки pplib++ выполните следующие шаги:

Добавьте в проект папки Dashboard, Datasources, ExpressAnalysis и Procedural, входящие в состав статического демо-проекта MobileAnalysisDemo, вместе с содержащимися в них файлами. Так, например, папки Dashboard, ExpressAnalysis и Procedural можно взять отсюда: components-*/prognoz-mobileappios/Sources/, а папку Datasources - по следующему пути: components-*/prognoz-mobileappios/Sources/ExpressAnalysis/Datasources.

Замените в файле статичного примера GridDataViewDatasource.m код, реализующий методы gridView:valueForHeaderForRow:number: и gridView:valueForHeaderForColumn:number:, на фрагмент кода, приведённый в раскрывающемся списке.

Заменяющий фрагмент кода для файла GridDataViewDataSource.m

Также необходимо заменить расширение файла GridDataViewDatasource.m на расширение .mm.

- (NSObject *)gridView:(NuGridView *)gridView valueForHeaderForRow:(NSInteger)row number:(NSInteger)number {
    SPPLPivotTableHeader leftTableHeader = m_pivotTable->leftHeader();
    SPPLPivotTableHeaderElements elements = leftTableHeader->elements();
    SPPLPivotTableHeaderElement element = elements->getElementByIndex(row);
    
    if (elements->isElementInTotals(element)) {
        SPPLPivotTableTotalsHeaderElement totalsElement = element->qClass<PPLPivotTableTotalsHeaderElement>();
        NSString *pattern = [self namePatternByTotalType:totalsElement->type()];
        if (totalsElement->isByLevelsTotals()) {
            NSString *levelText = NSLocalizedString(@"Level", @"Level");
            return [NSString stringWithFormat:@"%@ (%@ %d)", pattern, levelText,totalsElement->level()];
        }
        else {
            if (element->correspondingDimensionElements() != NULL && element->correspondingDimensionElements()->count() > 0) {
                SPPLDimensionElement lastParentElement = element->correspondingDimensionElements()->lastObject<PPLDimensionElement>();
                return [NSString stringWithFormat:@"%@ (%@)", pattern, lastParentElement->name()->nsString()];
            }
            else {
                return pattern;
            }
        }
    }
    else if (elements->isElementCalculated(element)) {
        SPPLPivotTableCalculatedHeaderElement calculatedElement = element->qClass<PPLPivotTableCalculatedHeaderElement>();
        // Получаем контейнер настроек вычисляемых рядов
        SPPLPivotTableCalculatorSettings settings = m_pivotTable->calculatorSettings();
        if (settings != nil) {
            // Создаём копию контейнера настроек вычисляемых рядов
            settings = settings->copy()->qClass<PPLPivotTableCalculatorSettings>();
            // Удаляем все настройки из текущего контейнера вычисляемых рядов
            if (settings->settingsCount() > 0) {
                SPPLPivotTableCalculatorSetting setting = settings->setting(0);
                settings->removeSetting(setting);
            }
            } else {
            // Создаём новый контейнер настроек вычисляемых рядов
            settings = new PPLPivotTableCalculatorSettings();
        }
        // Добавляем настройку в контейнер настроек вычисляемых рядов
        settings->addSetting(calculatedElement->calculatorSetting());
        
        NSString *pattern = [self namePatternByCalculatorType:settings->setting(0)->type()];
        SPPLPivotTableHeaderElement parentElement = elements->getParentElement(element);
        SPPLDimensionElement lastParentElement = parentElement->correspondingDimensionElements()->lastObject<PPLDimensionElement>();
        return [NSString stringWithFormat:@"%@ (%@)", pattern, lastParentElement->name()->nsString()];
    }
    else {
        SNArray correspondingDimensionElements = element->correspondingDimensionElements();
        if (correspondingDimensionElements->count() > number) {
            SPPLDimensionElement dimensionElement = correspondingDimensionElements->objectAtIndex<PPLDimensionElement>(number);
            return dimensionElement->name()->nsString();
        }
        else {
            return nil;
        }
    }
}
- (NSObject *)gridView:(NuGridView *)gridView valueForHeaderForColumn:(NSInteger)column number:(NSInteger)number {
    if (column == SPARKLINE_COLUMN_NUMBER) {
        return NSLocalizedString(@"Sparklines", @"Sparklines");
    }
    else {
        SPPLPivotTableHeader topTableHeader = m_pivotTable->topHeader();
        SPPLPivotTableHeaderElements elements = topTableHeader->elements();
        SPPLPivotTableHeaderElement element = elements->getElementByIndex(column);
        
        if (elements->isElementInTotals(element)) {
            // Создаём итоговый элемент заголовка таблицы
            SPPLPivotTableTotalsHeaderElement qElement = element->qClass<PPLPivotTableTotalsHeaderElement>();
            SPPLPivotTableTotalsHeaderElement totalsElement = PPLPivotTableTotalsHeaderElement::totalsHeaderElement(element->correspondingDimensionElements(), NULL, qElement->type(), qElement->totalsIndex(), 0, qElement->level());
            // Получаем шаблон для наименования итогового элемента заголовка таблицы
            NSString *pattern = [self namePatternByTotalType:totalsElement->type()];
            // Проверяем, рассчитываются ли итоги по уровням измерений
            if (totalsElement->isByLevelsTotals()) {
                NSString *levelText = NSLocalizedString(@"Level", @"Level");
                return [NSString stringWithFormat:@"%@ (%@ %d)", pattern, levelText,totalsElement->level()];
            }
            else {
                if (element->correspondingDimensionElements() != NULL && element->correspondingDimensionElements()->count() > 0) {
                    SPPLDimensionElement lastParentElement = element->correspondingDimensionElements()->lastObject<PPLDimensionElement>();
                    return [NSString stringWithFormat:@"%@ (%@)", pattern, lastParentElement->name()->nsString()];
                }
                else {
                    return pattern;
                }
            }
        }
        else if (elements->isElementCalculated(element)) {
            // Приведём элемент к типу PPLPivotTableCalculatedHeaderElement
            SPPLPivotTableCalculatedHeaderElement qElement = element->qClass<PPLPivotTableCalculatedHeaderElement>();
            // Определяем настройки вычисляемого элемента
            SPPLPivotTableCalculatorMutableSetting calculatorSetting = new PPLPivotTableCalculatorMutableSetting();
            // Устанавливаем тип вычисляемого ряда таблицы данных
            calculatorSetting->setType(qElement->calculatorSetting()->type());
            // Устанавливаем элемент заголовка таблицы, соответствующий строке или столбцу с вычисляемым рядом
            calculatorSetting->setRelatedTableElement(element);
            // Устанавливаем индекс вычисляемого элемента
            calculatorSetting->setRelatedData(NNumber::numberWithInteger(qElement->calculatorIndex()));
            // Создаём новый вычисляемый элемент заголовка на основе настроек исходного элемента
            SPPLPivotTableCalculatedHeaderElement calculatedElement = PPLPivotTableCalculatedHeaderElement::calculatedHeaderElement(calculatorSetting->relatedTableElement(), calculatorSetting, calculatorSetting->relatedData<NNumber>()->integerValue());
            
            NSString *pattern = [self namePatternByCalculatorType:calculatorSetting->type()];
            SPPLPivotTableHeaderElement parentElement = elements->getParentElement(element);
            SPPLDimensionElement lastParentElement = parentElement->correspondingDimensionElements()->lastObject<PPLDimensionElement>();
            return [NSString stringWithFormat:@"%@ (%@)", pattern, lastParentElement->name()->nsString()];
        }
        else {
            SNArray correspondingDimensionElements = element->correspondingDimensionElements();
            if (correspondingDimensionElements->count() > number) {
                SPPLDimensionElement dimensionElement = correspondingDimensionElements->objectAtIndex<PPLDimensionElement>(number);
                return dimensionElement->name()->nsString();
            }
            else {
                return nil;
            }
        }
    }
}

Добавьте в настройках проекта ссылки на следующие платформы и библиотеку:
- CFNetwork.framework;
- libsqlite3.dylib;
- MapKit.framework;
- MessageUI.framework;
- MobileAnalysis.framework;
- OpenGLES.framework;
- SystemConfiguration.framework.
Примечание. Для подключения платформ и библиотек необходимо в настройках цели проекта перейти на вкладку «Build Phases», раскрыть раздел «Link Binary With Libraries» и добавить в список указанные выше платформы и библиотеки.
Укажите путь к заголовочным файлам платформы MobileAnalysis.framework в настройке построения цели проекта «User Header Search Paths» (например, путь «$(SRCROOT)/../Frameworks/MobileAnalysis.framework/Headers»).

Примечание. Настройки построения цели проекта находятся на вкладке «Build Settings».
В настройках построения цели проекта для параметра «Mismatched Return Type» укажите значение «YES».
В настройках построения цели проекта для параметра «C++ Language Dialect» укажите значение «C++ 11 [-std=c++11]».
В настройках построения цели проекта для параметра «C++ Standard Library» укажите значение «libc++ (LLVM C++ standard library with C++11 support)».
В настройках построения цели проекта для параметра «Enable C++ Exceptions» укажите значение «YES».
В настройках построения цели проекта для параметра «Enable C++ Runtime Types» укажите значение «NO».
Убедитесь, что в настройках построения цели проекта отключена опция «Objective-C Automatic Reference Counting».
Добавьте в проект следующие папки вместе с их содержимым:
- ClassFactory;
- Resources.
В цели проекта укажите в настройке «Other Linker Flags» значение «-ObjC».