IStatistics.DurbinWatsonProbabilities

Синтаксис Fore

DurbinWatsonProbabilities(DW: Double; N: Integer; K: Integer; Var pL: Double; Var pU: Double);

Синтаксис Fore.NET

DurbinWatsonProbabilities(DW: double; N: integer; K: integer; var pL: double; var pU: double);

Параметры

DW. Статистика Дарбина-Уотсона;

N. Количество наблюдений;

K. Количество переменных в модели, включая константу;

pL. Значение вероятности нижней границы интервала статистики Дарбина-Уотсона;

pU. Значение вероятности верхней границы интервала статистики Дарбина-Уотсона.

Описание

Метод DurbinWatsonProbabilities производит расчет значений вероятности границ интервала статистики Дарбина-Уотсона.

Комментарии

После выполнения метода параметры pL и pU примут значения вероятности нижней и верхней границ интервала статистики Дарбина-Уотсона.

Если статистика DW > 2, то расчет вероятностей осуществляется для величины DW' = 4 - DW и заключение делается об отрицательной автокорреляции остатков.

При N ≤ 60 вероятности рассчитываются по алгоритму Пана (Pan’s algorithm), при N > 60 - с помощью нормальной аппроксимации.

Интерпретация результатов:

Пусть α – заданный уровень значимости (1, 2.5 или 5%):

• Если pl≤ α, нулевая гипотеза отвергается, можно говорить о наличии автокорреляции остатков;

• Если pl > α, и pu ≤ α имеет место неопределённость;

• Если pl > α, нулевая гипотеза не отвергается, можно говорить о том, что автокорреляция отсутствует.

Пример Fore

Добавьте ссылку на системную сборку Stat.

Sub UserProc;
Var 
    Stat: Statistics;
    N, K, alpha: Integer;
    DW, pU, pL: Double;
Begin
    Stat := New Statistics.Create;
    // Зададим количество наблюдений
    N := 20;
    // Зададим количество переменных в модели
    K := 5;
    // Зададим значение статистики Дарбина-Уотсона
    DW := 1.6;
    // Произведем расчет значений вероятности нижней и верхней границ интервала статистики Дарбина-Уотсона
    Stat.DurbinWatsonProbabilities(DW, N, K, pL, pU);
    // Выведем нижнюю и верхнюю границы интервала
    Debug.WriteLine("Вероятность нижней границы интервала: " + pL.ToString);
    Debug.WriteLine("Вероятность верхней границы интервала: " + pU.ToString);
    //Проверка гипотезы на уровне значимости 5%
    alpha := 5;
    Debug.WriteLine("Проверка гипотезы:");
    If( pL <= alpha/100 )Then
        Debug.WriteLine("Нулевая гипотеза отвергается, коэф. автокорреляции p <> 0, есть автокорреляция остатков");
    End If;
    If(( pL > alpha/100 )And( pU <= alpha/100 ))Then
        Debug.WriteLine(" Неопределённость ");
    End If;
    If( pU > alpha/100 )Then
        Debug.WriteLine("Нулевая гипотеза принимается, коэф. автокорреляции р = 0, автокорреляции остатков нет");
    End If;
End Sub UserProc;

В результате выполнения примера в окно консоли будут выведены значения вероятности нижней и верхней границ интервала статистики Дарбина-Уотсона, будет совершена проверка гипотезы о наличии автокорреляции остатков.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Stat;
…
Public Shared Sub Main(Params: StartParams);
Var
    Stat: Statistics;
    N, K, alpha: Integer;
    DW, pU, pL: Double;
Begin
    Stat := New Statistics.Create();
    // Зададим количество наблюдений
    N := 20;
    // Зададим количество переменных в модели
    K := 5;
    // Зададим значение статистики Дарбина-Уотсона
    DW := 1.6;
    // Произведем расчет значений вероятности нижней и верхней границ интервала статистики Дарбина-Уотсона
    Stat.DurbinWatsonProbabilities(DW, N, K, Var pL, Var pU);
    // Выведем нижнюю и верхнюю границы интервала
    System.Diagnostics.Debug.WriteLine("Вероятность нижней границы интервала: " + pL);
    System.Diagnostics.Debug.WriteLine("Вероятность верхней границы интервала: " + pU);
    //Проверка гипотезы на уровне значимости 5%
    alpha := 5;
    System.Diagnostics.Debug.WriteLine("Проверка гипотезы:");
    If (pL <= alpha / 100) Then
        System.Diagnostics.Debug.WriteLine("Нулевая гипотеза отвергается, " +
            "коэф.автокорреляции p <> 0, есть автокорреляция остатков" );
    End If;
    If ((pL > alpha / 100) And (pU <= alpha / 100)) Then
        System.Diagnostics.Debug.WriteLine(" Неопределённость ");
    End If;
    If (pU > alpha / 100) Then
        System.Diagnostics.Debug.WriteLine("Нулевая гипотеза принимается, " +
            "коэф.автокорреляции р = 0, автокорреляции остатков нет" );
    End If;
End Sub;

См. также:

IStatistics | Тест Дарбина-Уотсона