IPPSpeedometer.BorderWidth

Синтаксис Fore

BorderWidth: Double;

Синтаксис Fore.NET

BorderWidth: double;

Описание

Свойство BorderWidth определяет толщину границы области спидометра.

Комментарии

Свойство BorderWidth актуально, если у свойства IPPSpeedometer.EnableBorder установлено значение True.

Пример Fore

Для выполнения примера предполагается наличие в репозитории аналитической панели с идентификатором «ADHOC». Аналитическая панель должна содержать спидометр.

Добавьте ссылки на системные сборки: Adhoc, Drawing, Express, Metabase и Speedometer.

Sub UserProc;
Var
    Speedometer: IPPSpeedometer;
    MB: IMetabase;
    AdhocReport: IAdhocReport;
    EaxSpeedometer: IEaxSpeedometer;
    Enalyzer: IEaxAnalyzer;
    DsObjs: IAdhocDataSourceObjects;
    SolidBrush: IGxSolidBrush;
    Color: IGxColor;
Begin
    MB := MetabaseClass.Active;
    // Получим аналитическую панель
    AdhocReport := MB.ItemById("ADHOC").Edit As IAdhocReport;
    // Получим источники данных аналитической панели
    DsObjs := AdhocReport.DataSourceObjects;
    // Получим спидометр
    Enalyzer := DsObjs.Item(0).GetSourceObject As IEaxAnalyzer;
    EaxSpeedometer := Enalyzer.Speedometer;
    // Получим параметры спидометра
    Speedometer := EaxSpeedometer.Speedometer;
    // Настроим параметры границы области спидометра
    Speedometer.EnableBorder := True;
    Speedometer.BorderWidth := 10;
    Speedometer.BorderStyle := GxDashStyle.Dot;
    // Настроим цвет границы области спидометра
    Color := New GxColor.CreateRGB(255,0,0);
    SolidBrush := New GxSolidBrush.Create(Color);
    Speedometer.BorderBrush := SolidBrush;
    (Enalyzer As IMetabaseObject).Save;
End Sub UserProc;

В результате выполнения примера будет добавлена граница области спидометра. Будут настроены ширина, стиль и цвет линии границы.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.AdHoc;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Speedometer;
Imports Prognoz.Platform.Interop.Drawing;
…
Public Shared Sub Main(Params: StartParams);
Var
    Speedometer: IPPSpeedometer;
    MB: IMetabase;
    AdhocReport: IAdhocReport;
    EaxSpeedometer: IEaxSpeedometer;
    Enalyzer: IEaxAnalyzer;
    DsObjs: IAdhocDataSourceObjects;
    SolidBrush: GxSolidBrushClass;
    Color: GxColorClass;
    BorderColor: GxColor;
Begin
    MB := Params.Metabase;
    // Получим аналитическую панель
    AdhocReport := MB.ItemById["ADHOC"].Edit() As IAdhocReport;
    // Получим источники данных аналитической панели
    DsObjs := AdhocReport.DataSourceObjects;
    // Получим спидометр
    Enalyzer := DsObjs.Item[0].GetSourceObject() As IEaxAnalyzer;
    EaxSpeedometer := Enalyzer.Speedometer;
    // Получим параметры спидометра
    Speedometer := EaxSpeedometer.Speedometer;
    // Настроим параметры границы области спидометра
    Speedometer.EnableBorder := True;
    Speedometer.BorderWidth := 10;
    Speedometer.BorderStyle := GxDashStyle.gdsDot;
    // Настроим цвет границы области спидометра
    Color := New GxColorClassClass();
    BorderColor := Color.FromKnownColor(GxKnownColor.clRed);
    SolidBrush := New GxSolidBrushClass();
    SolidBrush.Color := BorderColor;
    Speedometer.BorderBrush := SolidBrush;
    (Enalyzer As IMetabaseObject).Save();
End Sub;

См. также:

IPPSpeedometer