ILanerTable.CellRevisionDimension

Синтаксис Fore

CellRevisionDimension(Row: Integer; Column: Integer): IDimInstance;

Синтаксис Fore.NET

CellRevisionDimension[Row: Integer; Column: Integer]: Prognoz.Platform.Interop.Dimensions.IDimInstance;

Параметры

Row. Индекс строки.

Column. Индекс столбца.

Описание

Свойство CellRevisionDimension возвращает справочник, содержащий данные о ревизиях для указанной ячейки.

Пример Fore

Для выполнения примера предполагается наличие формы, расположенной на ней кнопки с идентификатором «Button1», компонента LanerBox и компонента UiErAnalyzer с идентификатором «UiErAnalyzer1», являющегося источником данных для LanerBox. В «UiErAnalyzer1» должна быть загружена рабочая книга базы данных временных рядов. Добавьте ссылки на системную сборку «Dimensions».

Процедура является обработчиком события OnClick для кнопки «Button1».

Sub Button1OnClick(Sender: Object; Args: IMouseEventArgs);
Var
    Laner: ILaner;
    LanTbl: ILanerTable;
    RevDimInst: IDimInstance;
    Atts: IDimAttributesInstance;

    Elems: IDimElements;
    i, j: Integer;
    Atr: IDimAttributeInstance;
Begin
    Laner := UiErAnalyzer1.ErAnalyzer.Laner;
    LanTbl := Laner.Execute;
    // Получение справочника ревизий
    RevDimInst := LanTbl.CellRevisionDimension(0, 0);
    // Получение атрибутов справочника ревизий
    Atts := RevDimInst.Attributes;
    // Получение элементов справочника ревизий
    Elems := RevDimInst.Elements;
    // Вывод справочника ревизий в окно консоли
    For i := 0 To Elems.Count - 1 Do
        Debug.WriteLine("Элемент " + i.ToString);
        For j := 0 To Atts.Count - 1 Do
            Atr := Atts.Item(j);
            Debug.Write(Atr.Attribute.Name + ": ");
            Debug.WriteLine(Atr.Value(i));
        End For;
        Debug.WriteLine("");
    End For;
End Sub Button1OnClick;

После выполнения примера в окно консоли будет выведен справочник, содержащий данные о ревизиях, для ячейки, которая расположена в первой строке и первом столбце загруженной рабочей книги.

Пример Fore.NET

Для выполнения примера предполагается наличие .NET формы, расположенной на ней кнопки с идентификатором «button1», компонента LanerBoxNet и компонента UiErAnalyzerNet с идентификатором «uiErAnalyzerNet1», являющегося источником данных для LanerBoxNet. В «uiErAnalyzerNet1» должна быть загружена рабочая книга базы данных временных рядов.

Процедура является обработчиком события Click для кнопки «button1».

Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Laner;
…
Private Sub button1_Click(sender: System.Object; e: System.EventArgs);
Var
    Laner: ILaner;
    LanTbl: ILanerTable;
    RevDimInst: IDimInstance;
    Atts: IDimAttributesInstance;

    Elems: IDimElements;
    i, j: integer;
    Atr: IDimAttributeInstance;
Begin
    Laner := uiErAnalyzerNet1.ErAnalyzer.ErAnalyzer.Laner;
    LanTbl := Laner.Execute();
    // Получение справочника ревизий
    RevDimInst := LanTbl.CellRevisionDimension[0, 0];
    // Получение атрибутов справочника ревизий
    Atts := RevDimInst.Attributes;
    // Получение элементов справочника ревизий
    Elems := RevDimInst.Elements;
    // Вывод справочника ревизий в окно консоли
    For i := 0 To Elems.Count - 1 Do
        System.Diagnostics.Debug.WriteLine("Элемент " + i.ToString());
        For j := 0 To Atts.Count - 1 Do
            Atr := Atts.Item[j];
            System.Diagnostics.Debug.Write(Atr.Attribute.Name + ": ");
            System.Diagnostics.Debug.WriteLine(Atr.Value[i As UInt32]);
        End For;
        System.Diagnostics.Debug.WriteLine("");
    End For;
End Sub;

См. также:

ILanerTable