ICustomObjectResolver.WriteFromStream

Синтаксис Fore

WriteFromStream(Stream: IIOStream);

Синтаксис Fore.NET

WriteFromStream(Stream: System.IO.Stream);

Параметры

Stream. Поток, из которого будут получены данные для записи.

Описание

Метод WriteFromStream записывает данные в пользовательский объект из потока.

Комментарии

Для чтения данных из пользовательского объекта в поток используйте метод ICustomObjectResolver.ReadToStream.

Пример Fore

Для выполнения примера в файловой системе предполагается наличие файла обновления «C:\CustomObjData.pefx». Данный файл должен содержать пользовательский объект, в котором записаны какие-либо данные. Также предполагается наличие текстового файла «C:\From.txt», содержащего данные, которые должны быть записаны в пользовательский объект.

Добавьте ссылки на системные сборки: IO, Metabase.

Sub UserProc;
Var
    Mb: IMetabase;
    Update: IMetabaseUpdate;
    Progress: MyUpdateProgress;
Begin
    // Получаем текущий репозиторий
    Mb := MetabaseClass.Active;
    // Создаем обновление
    Update := Mb.CreateUpdate;
    // Загружаем параметры обновления из файла
    Update.LoadFromFileNF("C:\CustomObjData.pefx");
    // Создаем объект, реализующий события, которые происходят во время обновления
    Progress := New MyUpdateProgress.Create;
    // Выполняем обновление
    Update.ApplyEx(Progress, Null);
End Sub UserProc;

// Класс, реализующий события, которые происходят во время обновления
Class MyUpdateProgress: UpdateProgress
    // Событие, возникающее после применения обновления пользовательского объекта,
    // но до момента сохранения его в репозиторий
    Sub OnAfterApplyCustomObject(Resolver: ICustomObjectResolver);
    Var
        StreamR, StreamW: IFileStream;
    Begin
        // Создаем поток, связанный с текстовым файлом «C:\To.txt»
        StreamR := New FileStream.Create("C:\To.txt", FileOpenMode.Create, FileShare.DenyNone);
        // Читаем данные из пользовательского объекта в поток, связанный с файлом
        Resolver.ReadToStream(StreamR);
        // Создаем поток, связанный с текстовым файлом «C:\From.txt»
        StreamW := New FileStream.Create("C:\From.txt", FileOpenMode.Read, FileShare.DenyNone);
        // Записываем данные в пользовательский объект из потока, связанного с файлом
        Resolver.WriteFromStream(StreamW);
    End Sub OnAfterApplyCustomObject;
    
End Class MyUpdateProgress;

В результате выполнения примера будет применено обновление «C:\CustomObjData.pefx». С помощью потока данные из пользовательского объекта в обновлении будут выгружены в файл «C:\To.txt», а в объект будут записаны данные из файла «C:\From.txt».

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    Update: IMetabaseUpdate;
    Progress: MyUpdateProgress;
Begin
    // Получаем текущий репозиторий
    Mb := Params.Metabase;
    // Создаем обновление
    Update := Mb.CreateUpdate();
    // Загружаем параметры обновления из файла
    Update.LoadFromFileNF("C:\CustomObjData.pefx", UpdateLoadMode.ulmReplace);
    // Создаем объект, реализующий события, которые происходят во время обновления
    Progress := New MyUpdateProgress.Create();
    // Выполняем обновление
    Update.ApplyEx(Progress, Null);
End Sub;

// Класс, реализующий события, которые происходят во время обновления
Public Class MyUpdateProgress: IMetabaseUpdateProgress
    // Событие, возникающее после применения обновления пользовательского объекта,
    // но до момента сохранения его в репозиторий
    Sub OnAfterApplyCustomObject(Resolver: ICustomObjectResolver);
    Var
        StreamR, StreamW: IFileStream;
    Begin
        // Создаем поток, связанный с текстовым файлом «C:\To.txt»
        StreamR := New FileStream.Create();
        StreamR.Create("C:\To.txt", FileOpenMode.frCreate, FileShare.frDenyNone);
        // Читаем данные из пользовательского объекта в поток, связанный с файлом
        Resolver.ReadToStream(StreamR As System.IO.Stream);
        // Создаем поток, связанный с текстовым файлом «C:\From.txt»
        StreamW := New FileStream.Create();
        StreamW.Create("C:\From.txt", FileOpenMode.frRead, FileShare.frDenyNone);
        // Записываем данные в пользовательский объект из потока, связанного с файлом
        Resolver.WriteFromStream(StreamW As System.IO.Stream);
    End Sub OnAfterApplyCustomObject;
    
    Public Sub OnProgress(Data: IMetabaseUpdateProgressData);
    Begin
    End Sub;
    
    Public Sub OnError(Data: IMetabaseUpdateProgressData; Var Ignore: Boolean);
    Begin
    End Sub;
    
    Public Sub OnAskConstraintsHandling(Node: IMetabaseUpdateNode; Details: String; Var Handling: UpdateDataConstraintsHandlingType);
    Begin
    End Sub;
    
    Public Sub OnAskReflectRights(Var Cancel: Boolean);
    Begin
    End Sub;
    
    Public Sub OnContext(Context: IMetabaseUpdateContext);
    Begin
    End Sub;
    
    Public Sub OnResolve(Node: IMetabaseUpdateNode; Resolver: IMetabaseUpdateResolver);
    Begin
    End Sub;
    
    Public Sub OnSkip(Data: IMetabaseUpdateProgressData);
    Begin
    End Sub;
    
    Public Sub OnNullLinks(Node: IMetabaseUpdateNode; Links: IMetabaseUpdateNullLinks);
    Begin
    End Sub;
    
    Public Sub OnBeforeCustomObjectSaveToPef(Resolver: ICustomObjectResolver);
    Begin
    End Sub;
End Class MyUpdateProgress;

См. также:

ICustomObjectResolver