IPrxDataIslandProperties.FormatConditions

Синтаксис Fore

FormatConditions : IPrxFormatConditions;

Синтаксис Fore.NET

FormatConditions : Prognoz.Platform.Interop.Report.IPrxFormatConditions;

Описание

Свойство FormatConditions определяет параметры условного форматирования данных.

Пример Fore

Для выполнения примера предполагается наличие регламентного отчета с идентификатором «REPORT», который содержит область данных. Добавьте ссылки на системные сборки: Metabase, Report, Drawing, Tab.

Sub UserProc;
Var
    MB: IMetabase;
    MObj: IMetabaseObject;
    Prop: IPrxDataIslandProperties;
    TabFormat : ITabFormatCondition;
    ValFormat : ITabFormatValues;
    DI: IPrxDataIsland;
Begin
    MB := MetabaseClass.Active;
    MObj := MB.ItemById("REPORT").Edit;
    DI := (MObj As IPrxReport).DataIslands.Item[0].Edit;
        Prop := DI.Properties;
        TabFormat := Prop.FormatConditions.Add;
        TabFormat.Type := TabConditionType.Values;
        ValFormat := TabFormat.Details As ITabFormatValues;
        // Трехцветный градиент для форматирования ячеек.
        ValFormat.Style := TabFormatValuesStyle.ThreeColorScale;
        // Настройка минимального значения.
        ValFormat.MinValueType := TabFormatValueType.Lowest;
        ValFormat.MinValueColor := GxColor.FromName("Red");
        // Настройка среднего значения.
        ValFormat.MidValueType := TabFormatValueType.Percent;
        ValFormat.MidValue := 50;
        ValFormat.MidValueColor := GxColor.FromName("Blue");
        // Настройка максимального значения.
        ValFormat.MaxValueType := TabFormatValueType.Highest;
        ValFormat.MaxValueColor := GxColor.FromName("Green");
    DI.Save;
    // Сохраняем отчет.
    MObj.Save;
End Sub UserProc;

После выполнения примера для области данных будет определено условное форматирование ячеек на основе их значений: стиль оформления - трехцветный градиент.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Report;
Imports Prognoz.Platform.Interop.Tab;
Imports Prognoz.Platform.Interop.Drawing;

...

Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    MObj: IMetabaseObject;
    Prop: IPrxDataIslandProperties;
    TabFormat : ITabFormatCondition;
    ValFormat : ITabFormatValues;
    Color : GxColorClass = New GxColorClassClass();
    DI: IPrxDataIsland;
Begin
    MB := Params.Metabase;
    MObj := MB.ItemById["REPORT"].Edit();
    DI := (MObj As IPrxReport).DataIslands.Item[0].Edit();
        Prop := DI.Properties;
        TabFormat := Prop.FormatConditions.Add();
        TabFormat.Type := TabConditionType.tctValues;
        ValFormat := TabFormat.Details As ITabFormatValues;
        // Трехцветный градиент для форматирования ячеек.
        ValFormat.Style := TabFormatValuesStyle.tfvsThreeColorScale;
        // Настройка минимального значения.
        ValFormat.MinValueType := TabFormatValueType.tfvtLowest;
        ValFormat.MinValueColor := Color.FromName("Red");
        // Настройка среднего значения.
        ValFormat.MidValueType := TabFormatValueType.tfvtPercent;
        ValFormat.MidValue := 50;
        ValFormat.MidValueColor := Color.FromName("Blue");
        // Настройка максимального значения.
        ValFormat.MaxValueType := TabFormatValueType.tfvtHighest;
        ValFormat.MaxValueColor := Color.FromName("Green");
    DI.Save();
    // Сохраняем отчет.
    MObj.Save();
End Sub;

См. также:

IPrxDataIslandProperties | ITabFormatValues