IPrxChart.Points

Синтаксис

Points: String;

Описание

Свойство Points определяет адрес диапазона, из которого будут браться наименования точек диаграммы.

Пример Fore

Для выполнения примера предполагается наличие диаграммы в регламентном отчете с идентификатором REGULAR_REPORT_POINTS и данных в ячейках B4:F8, A4:A8 и B1:F1. Подключите системные сборки: Metabase, Report, Tab, Drawing.

Sub UserProc;
Var
    Report: IPrxReport;
    Chart: IPrxChart;
    Sheet: ITabSheet;
    MB: IMetabase;
    Style: ITabCellStyle;
    Arr: array Of integer;
    i: integer;
Begin
    //Подключение к регламентному отчету
    MB := MetabaseClass.Active;
    Report := MB.ItemById("REGULAR_REPORT_POINTS").Edit As IPrxReport;
    Sheet := (Report.Sheets.Item(0) As IPrxTable).TabSheet;
    Chart := Sheet.Objects.Item(0).Extension As IPrxChart;
    //Определение диапазона числовых данных, наименования рядов и точек
    Chart.Data := "B4:F8";
    Chart.Series := "A4:A8";
    Chart.Points := "B1:F1";
    //Отключение функции "Автоматически изменять диапазоны" данных диаграммы
    Chart.AutoAdjust := False;
    //Диапазон таблицы данных, по которым строится диаграмма, закрашивается в заданный цвет
    Style := Chart.DataRange.Style;
    Style.BackgroundColor := New GxColor.CreateRGB(164,199,252);
    //Определение скрытых данных на оси категорий
    Arr := Chart.ExcludedPoints;
    Debug.WriteLine("Cкрытые точки: ");
    For Each i In Arr Do
        Debug.WriteLine(Chart.PointNameByIndex(i));            
    End For;
    //Отключение функции "Отображать скрытые данные" диаграммы
    Chart.IncludeHidden := False;
    (Report As IMetabaseObject).Save;
End Sub UserProc;

В регламентном отчете будут изменены исходные данные диаграммы.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Report;
Imports Prognoz.Platform.Interop.Tab;
Imports Prognoz.Platform.Interop.Drawing;

Public Shared Sub Main(Params: StartParams);
Var
    Report: IPrxReport;
    Chart: IPrxChart;
    Sheet: ITabSheet;
    MB: IMetabase;
    Style: ITabCellStyle;
    BackgroundColor: GxColor;
    Arr: Array;
    i: integer;
Begin
    //Подключение к регламентному отчету
    MB := Params.Metabase;
    Report := MB.ItemById["REGULAR_REPORT_POINTS"].Edit() As IPrxReport;
    Sheet := (Report.Sheets.Item[0] As IPrxTable).TabSheet;
    Chart := Sheet.Objects.Item[0].Extension As IPrxChart;
    //Определение диапазона числовых данных, наименования рядов и точек
    Chart.Data := "B4:F8";
    Chart.Series := "A4:A8";
    Chart.Points := "B1:F1";
    //Отключение функции "Автоматически изменять диапазоны" данных диаграммы
    Chart.AutoAdjust := False;
    //Диапазон таблицы данных, по которым строится диаграмма, закрашивается в заданный цвет
    Style := Chart.DataRange.Style;
    BackgroundColor := New GxColor();
    BackgroundColor.CreateRGB(164, 199, 252);
    Style.BackgroundColor := BackgroundColor;
    //Определение скрытых данных на оси категорий
    Arr := Chart.ExcludedPoints;
    System.Diagnostics.Debug.WriteLine("Cкрытые точки: ");
    For Each i In Arr Do
        System.Diagnostics.Debug.WriteLine(Chart.PointNameByIndex[i]);
    End For;
    //Отключаем отображение скрытых данных
    Chart.IncludeHidden := False;
    (Report As IMetabaseObject).Save();
End Sub;

См. также:

IPrxChart