IPivotTable.Post

Синтаксис

Post([Callback: ICubeCallback = Null]);

Параметры

Callback. Объект, осуществляющий обработку ошибок, которые могут возникнуть при сохранении данных.

Описание

Метод Post осуществляет выход из режима редактирования с сохранением измененных данных таблицы.

Комментарии

Если сохранение выполняется из аналитической панели или экспресс-отчёта, отображающего данные из базы данных временных рядов с выбранным вариантом отображения «Атрибуты», то сохранение значений доступно для:

• атрибутов наблюдений;

• атрибутов, не являющихся ссылкой на справочник или не являющихся атрибутами данного справочника;

• атрибутов, имеющих только единичное значение.

Пример

Для выполнения примера предполагается наличие формы, расположенной на ней кнопки с идентификатором «Button1», компонента TabSheetBox и компонента UiErAnalyzer с идентификатором «UiErAnalyzer1», являющегося источником данных для TabSheetBox.

Class SaveCallback: Object, ICubeCallback
    Public Sub OnCallback(Argument: ICubeCallbackArgument);
    Begin
        Debug.WriteLine("Ошибка: " + Argument.Error.Message);
        Debug.WriteLine("Идентификатор ошибки: " + Argument.Error.MessageID.ToString);
        Debug.WriteLine("Источник: " + Argument.Error.Source);
        Argument.IgnoreError := True;
    End Sub OnCallback;
    
    Public Function get_Argument: ICubeCallbackArgument;
    Begin
        Return Null;
    End Function get_Argument;
End Class SaveCallback;

Sub Button1OnClick(Sender: Object; Args: IMouseEventArgs);
Var
    CallBack: SaveCallback;
    OLAP: IEaxAnalyzer;
    Pivot: IPivot;
    Table: IPivotTable;
    i, j: Integer;
Begin
    CallBack := New SaveCallback.Create;
    OLAP := UiErAnalyzer1.ErAnalyzer;
    Pivot := OLAP.Pivot;
    Table := Pivot.ObtainTable;
    Table.Edit;
    For i := 0 To Table.RowCount - 1 Do
        For j := 0 To Table.ColumnCount - 1 Do
            Table.Cell(i, j) := Math.RandBetweenI(100, 500);
        End For;
    End For;
    Table.Post(CallBack);
    Pivot.Refresh;
End Sub Button1OnClick;

После выполнения примера при нажатии на кнопку будут сгенерированы случайные значения для всех ячеек таблицы. Обновленные данные будут сохранены в источник данных. Ошибки, которые могут возникнуть при сохранении, будут обрабатываться в пользовательском классе «SaveCallback».

См. также:

IPivotTable