IValidationMissingData.SeriesMode

Синтаксис Fore

SeriesMode: ValidationMissingDataSeriesMode;

Синтаксис Fore.NET

SeriesMode: Prognoz.Platform.Interop.Ms.ValidationMissingDataSeriesMode;

Описание

Свойство SeriesMode определяет режим выгрузки выявленных исключений.

Комментарии

По умолчанию исключения выгружаются на все точки, содержащие пустые значения, то есть свойство имеет значение ValidationMissingDataSeriesMode.None.

Пример Fore

Для выполнения примера в репозитории предполагается наличие базы данных временных рядов с идентификатором «TSDB_VALIDATION_PARAMETERS», содержащей правило валидации с идентификатором «VALIDATION».

Добавьте ссылки на системные сборки: Cubes, Dimensions, Drawing, Laner, Metabase, Ms, Tab.

Sub UserProc;
Var
    Mb: IMetabase;
    RubrKey: Integer;
    ValidObj: IMetabaseObject;
    ValidFilter: IValidationFilter;
    FilterSett: IValidationFilterSettings;
    Color: IGxColor;
    Brush: IGxSolidBrush;
    MissingData: IValidationMissingData;
    SelectionValList: IValidationSelectionValueList;
    SelectionFilter: IValidationSelectionFilter;
Begin
    Mb := MetabaseClass.Active;
    RubrKey := Mb.GetObjectKeyById("TSDB_VALIDATION_PARAMETERS");
    // Получаем правило валидации
    ValidObj := Mb.ItemByIdNamespace("VALIDATION", RubrKey).Edit;
    ValidFilter := ValidObj As IValidationFilter;
    // Валидация выполняется по годовым данным
    ValidFilter.Level := DimCalendarLevel.Year;
    // Получаем настройки правила валидации
    FilterSett := ValidFilter.Settings;
    // Задаём оформление исключений
    Color := New GxColor.CreateRGB(218, 150, 148);
    Brush := New GxSolidBrush.Create(Color);
    FilterSett.CellStyle.TabStyle.BackgroundBrush := Brush;
    // Задаём тип валидации: «Пропуски в данных»
    ValidFilter.Kind := ValidationDetailsKind.MissingData;
    // Настраиваем параметры валидации
    MissingData := ValidFilter.Details As IValidationMissingData;
    // Задаём область выявления пропусков
    MissingData.Type := ValidationMissingDataType.InData;
    MissingData.SeriesMode := ValidationMissingDataSeriesMode.None;
    // Указываем, что валидация выполняется по всей базе данных временных рядов
    SelectionValList := MissingData.SelectionTargetData;
    SelectionValList.Clear;
    // Очищаем фильтр валидации
    SelectionFilter := MissingData.SelectionFilter;
    SelectionFilter.Clear;
    // Сохраняем изменения в правиле
    ValidObj.Save;
End Sub UserProc;

В результате выполнения примера будет настроено правило валидации «Пропуски в данных». Данное правило будет выявлять пропуски внутри годовых данных.

Пример Fore.NET

Imports Prognoz.Platform.Interop.Cubes;
Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Drawing;
Imports Prognoz.Platform.Interop.Laner;
Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.Tab;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    RubrKey: uinteger;
    ValidObj: IMetabaseObject;
    ValidFilter: IValidationFilter;
    FilterSett: IValidationFilterSettings;
    
    Color: GxColor;
    Brush: IGxSolidBrush;
    MissingData: IValidationMissingData;
    SelectionValList: IValidationSelectionValueList;
    SelectionFilter: IValidationSelectionFilter;
Begin
    Mb := Params.Metabase;
    RubrKey := Mb.GetObjectKeyById("TSDB_VALIDATION_PARAMETERS");
    // Получаем правило валидации
    ValidObj := Mb.ItemByIdNamespace["VALIDATION", RubrKey].Edit();
    ValidFilter := ValidObj As IValidationFilter;
    // Валидация выполняется по годовым данным
    ValidFilter.Level := DimCalendarLevel.dclYear;
    // Получаем настройки правила валидации
    FilterSett := ValidFilter.Settings;
    // Задаём оформление исключений
    Color := New GxColorClass_2.Create();
    Color.CreateRGB(218, 150, 148);
    Brush := New GxSolidBrushClass.Create();
    Brush.Create(Color);
    FilterSett.CellStyle.TabStyle.BackgroundBrush := Brush;
    // Задаём тип валидации: «Пропуски в данных»
    ValidFilter.Kind := ValidationDetailsKind.vdkMissingData;
    // Настраиваем параметры валидации
    MissingData := ValidFilter.Details As IValidationMissingData;
    // Задаём область выявления пропусков
    MissingData.Type := ValidationMissingDataType.vmdtInData;
    MissingData.SeriesMode := ValidationMissingDataSeriesMode.vmdsmNone;
    // Указываем, что валидация выполняется по всей базе данных временных рядов
    SelectionValList := MissingData.SelectionTargetData;
    SelectionValList.Clear();
    // Очищаем фильтр валидации
    SelectionFilter := MissingData.SelectionFilter;
    SelectionFilter.Clear();
    // Сохраняем изменения в правиле
    ValidObj.Save();
End Sub;

См. также:

IValidationMissingData