IDmHighlightExceptions.Threshold

Синтаксис Fore

Threshold: Double;

Синтаксис Fore.NET

Threshold: double;

Описание

Свойство Threshold определяет пороговое значение для выявления исключений.

Комментарии

Диапазон допустимых значений: [0; 1].

Пороговое значение - это максимальная доля исключений, содержащихся в данных.

Пример Fore

Для выполнения примера в репозитории предполагается наличие таблицы с идентификатором «DM_TABLE», содержащей данные для анализа. Также должен присутствовать регламентный отчёт с идентификатором «DM_REPORT_RES», в который будут выгружены результаты анализа.

Добавьте ссылки на системные сборки: Metabase, Ms, Report, Stat, Tab.

Sub UserHiEx;
Var
    mb: IMetabase;
    ReportDS: IDmReportDataSource;
    TableDS: IDmTableDataSource;
    Method: IDmMethod;
    Report: IPrxReport;
    Shs: IPrxSheets;
    Sheet: ITabSheet;
    DM: IDmHighlightExceptions;
    i: Integer;
    Attrs: Array Of Integer;
    Reports: IDmReports;
    DmReport: IDmReport;
Begin
    mb := MetabaseClass.Active;
    // Создаем метод расчёта
    Method := (New DataMiningMethod.Create) As IDmMethod;
    // Указываем тип метода
    Method.Kind := DmMethodKind.HighlightExceptions;
    // Создаем табличный источник данных
    TableDS := (New TableDataSource.Create) As IDmTableDataSource;
    // Указываем таблицу-источник
    TableDS.Table := mb.ItemByID("DM_TABLE").Bind;
    // Задаем входной источник данных
    Method.InputDataSource := TableDS;
    // Создаем источник данных, являющийся регламентным отчётом
    ReportDS := (New ReportDataSource.Create) As IDmReportDataSource;
    // Задаем приёмник данных
    Method.OutputDataSource := ReportDS;
    // Настраиваем параметры метода расчёта
    DM := Method.Details As IDmHighlightExceptions;
    // Задаем факторы для поиска исключений
    Attrs := New Integer[TableDS.FieldCount];
    For i := 0 To Attrs.Length - 1 Do
        Attrs[i] := i;
    End For;
    DM.Attributes := Attrs;
    // Задаем пороговое значение
    DM.Threshold := 0.57;
    // Выполняем анализ и выгружаем результаты
    Reports := Method.Execute;
    DmReport := reports.FindByType(DmReportType.HighlightExceptions);
    ReportDS := DmReport.Generate;
    ReportDS.TabSheet.View.Selection.SelectAll;
    ReportDS.TabSheet.View.Selection.Copy;
    // Получаем регламентный отчет, в который будут выгружены результаты
    Report := mb.ItemByID("DM_REPORT_RES").Edit As IPrxReport;
    Shs := Report.Sheets;
    Shs.Clear;
    Sheet := (Shs.Add("", PrxSheetType.Table) As IPrxTable).TabSheet;
    Sheet.Table.Paste;
    Sheet.Columns(0, 1).AdjustWidth;
    Sheet.Rows(0, 1).AdjustHeight;
    Report.Sheets.Item(0).Name := ReportDS.Caption;
    // Сохраняем выгруженные денные
    (Report As IMetabaseObject).Save;
End Sub UserHiEx;

В результате выполнения примера для данных из таблицы «DM_TABLE» будет выполнен интеллектуальный анализ данных методом «Поиск исключений», результаты анализа выгружены в отчёт «DM_REPORT_RES».

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.Report;
Imports Prognoz.Platform.Interop.Stat;
Imports Prognoz.Platform.Interop.Tab;
…
Public Shared Sub Main(Params: StartParams);
Var
    mb: IMetabase;
    ReportDS: IDmReportDataSource;
    TableDS: IDmTableDataSource;
    Method: IDmMethod;
    Report: IPrxReport;
    Shs: IPrxSheets;
    Sheet: ITabSheet;
    DM: IDmHighlightExceptions;
    i: Integer;
    Attrs: Array Of Integer;
    Reports: IDmReports;
    DmReport: IDmReport;
Begin
    mb := Params.Metabase;
    // Создаем метод расчёта
    Method := (New DataMiningMethod.Create()) As IDmMethod;
    // Указываем тип метода
    Method.Kind := DmMethodKind.dmmkHighlightExceptions;
    // Создаем табличный источник данных
    TableDS := (New TableDataSource.Create()) As IDmTableDataSource;
    // Указываем таблицу-источник
    TableDS.Table := mb.ItemByID["DM_TABLE"].Bind();
    // Задаем входной источник данных
    Method.InputDataSource := TableDS;
    // Создаем источник данных, являющийся регламентным отчётом
    ReportDS := (New ReportDataSource.Create()) As IDmReportDataSource;
    // Задаем приёмник данных
    Method.OutputDataSource := ReportDS;
    // Настраиваем параметры метода расчёта
    DM := Method.Details As IDmHighlightExceptions;
    // Задаем факторы для поиска исключений
    Attrs := New Integer[TableDS.FieldCount];
    For i := 0 To Attrs.Length - 1 Do
        Attrs[i] := i;
    End For;
    DM.Attributes := Attrs;
    // Задаем пороговое значение
    DM.Threshold := 0.57;
    // Выполняем анализ и выгружаем результаты
    Reports := Method.Execute();
    DmReport := reports.FindByType[DmReportType.drtHighlightExceptions];
    ReportDS := DmReport.Generate();
    ReportDS.TabSheet.View.Selection.SelectAll();
    ReportDS.TabSheet.View.Selection.Copy();
    // Получаем регламентный отчет, в который будут выгружены результаты
    Report := mb.ItemByID["DM_REPORT_RES"].Edit() As IPrxReport;
    Shs := Report.Sheets;
    Shs.Clear();
    Sheet := (Shs.Add("", PrxSheetType.pstTable) As IPrxTable).TabSheet;
    Sheet.Table.Paste();
    Sheet.Columns[0, 1].AdjustWidth(-1, -1);
    Sheet.Rows[0, 1].AdjustHeight(-1, -1);
    Report.Sheets.Item[0].Name := ReportDS.Caption;
    // Сохраняем выгруженные денные
    (Report As IMetabaseObject).Save();
End Sub;

См. также:

IDmHighlightExceptions