IDescStatsBox.AddVariableStubFixedSlice

Синтаксис Fore

AddVariableStubFixedSlice(Stub: IVariableStub; VarDims: IDimSelectionSet);

Синтаксис Fore.NET

AddVariableStubFixedSlice(Stub: Prognoz.Platform.Interop.Cubes.IVariableStub; VarDims: Prognoz.Platform.Interop.Dimensions.IDimSelectionSet);

Параметры

Stub. Переменная, для которой необходимо произвести расчет описательных статистик;

VarDims. Отметка элементов по дополнительным измерениям.

Описание

Метод AddVariableStubFixedSlice осуществляет добавление в компонент переменной с указанием отметки по ее дополнительным измерениям.

Данный метод актуально использовать, если переменная имеет дополнительные измерения. В параметре VarDims указывается отметка по этим измерениям. Если переменная не имеет дополнительных измерений, то в качестве значения параметра VarDims можно указать значение Null.

Пример Fore

Для выполнения примера предполагается наличие формы, расположенной на ней кнопки с наименованием «Button1» и компонента DescStatsBox с наименованием «DescStatsBox1». В репозитории имеется контейнер моделирования с идентификатором «CONT_MODEL», содержащий переменную моделирования с идентификаторами «X1». Данная переменная имеет в своей структуре дополнительные измерения.

    Sub Button1OnClick(Sender: Object; Args: IMouseEventArgs);
    Var
        MB: IMetabase;
        MS, Var1: IMetabaseObject;
        Dims: IMsVariableDimensions;
        Dim: IMsVariableDimension;
        DimInst: IDimInstance;
        SelectionFact: IDimSelectionSetFactory;
        DimSS: IDimSelectionSet;
        DimSel: IDimSelection;
    Begin
        MB := MetabaseClass.Active;
        MS := MB.ItemById("CONT_MODEL").Bind;
        Var1 := MB.ItemByIdNamespace("X1", MS.Key).Bind;
        Dims := (Var1 As IMsVariable).Dimensions;
        //Создание новой отметки
        SelectionFact := New DimSelectionSetFactory.Create;
        DimSS := SelectionFact.CreateDimSelectionSet;
        For Each Dim In Dims Do
            //Отметка первых элементов по всем дополнительным измерениям
            DimInst := (Dim.Model As IMetabaseObject).Open(Null) As IDimInstance;
            DimSel := DimSS.Add(DimInst);
            DimSel.SelectElement(0, False);
        End For;
        //Подключение контейнера моделирования к компоненту DescStatsBox
        //и загрузка переменной моделирования
        DescStatsBox1.ModelSpace := MS As IMsModelSpace;
        DescStatsBox1.AddVariableStubFixedSlice(Var1 As IVariableStub, DimSS);
    End Sub Button1OnClick;

При нажатии на кнопку компонент «DescStatsBox1» будет подключен к контейнеру моделирования «CONT_MODEL». В список переменных компонента будет загружена переменная моделирования «X1». При загрузке в дополнительных измерениях переменной будут зафиксированы первые элементы.

Пример Fore.NET

Для выполнения примера предполагается наличие .NET-формы, расположенной на ней кнопки с наименованием «Button1» и компонента DescStatsBox с наименованием «DescStatsBox1». В репозитории имеется контейнер моделирования с идентификатором «CONT_MODEL», содержащий переменную моделирования с идентификаторами «X1». Данная переменная имеет в своей структуре дополнительные измерения.

Imports Prognoz.Platform.Interop.Cubes;
Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Ms;
//...
    Private Sub button1_Click(sender: System.Object; e: System.EventArgs);
    Var
        MB: IMetabase;
        MS, Var1: IMetabaseObject;
        Dims: IMsVariableDimensions;
        Dim: IMsVariableDimension;
        DimInst: IDimInstance;
        SelectionFact: IDimSelectionSetFactory;
        DimSS: IDimSelectionSet;
        DimSel: IDimSelection;
    Begin
        MB := Self.Metabase;
        MS := MB.ItemById["CONT_MODEL"].Bind();
        Var1 := MB.ItemByIdNamespace["X1", MS.Key].Bind();
        Dims := (Var1 As IMsVariable).Dimensions;
        //Создание новой отметки
        SelectionFact := New DimSelectionSetFactory();
        DimSS := SelectionFact.CreateDimSelectionSet();
        For Each Dim In Dims Do
            //Отметка первых элементов по всем дополнительным измерениям
            DimInst := (Dim.Model As IMetabaseObject).Open(Null) As IDimInstance;
            DimSel := DimSS.Add(DimInst);
            DimSel.SelectElement(0, False);
        End For;
        //Подключение контейнера моделирования к компоненту DescStatsBox
        //и загрузка переменной моделирования
        DescStatsBoxNet1.CtrlBox.ModelSpace := MS As IMsModelSpace;
        DescStatsBoxNet1.CtrlBox.AddVariableStubFixedSlice(Var1 As IVariableStub, DimSS);
    End Sub;

При нажатии на кнопку компонент «DescStatsBoxNet1» будет подключен к контейнеру моделирования «CONT_MODEL». В список переменных компонента будет загружена переменная моделирования «X1». При загрузке в дополнительных измерениях переменной будут зафиксированы первые элементы.

См. также:

IDescStatsBox