IMatrixIterator.Values

Синтаксис Fore

Values(Index: Integer): Variant;

Синтаксис Fore.NET

Values[Index: integer]: object;

Параметры

Index. Индекс атрибута, по которому хранится значение элемента матрицы.

Описание

Свойство Values определяет значение указанного атрибута для элемента матрицы, на котором в данный момент находится курсор итератора.

Комментарии

Свойство актуально при работе с матрицей показателей (IRubricatorExecuteResult.Factors) или значений (IRubricatorExecuteResult.Values), которые могут быть получены в результате расчёта базы данных временных рядов. Если при расчёте не заданы свойства IRubricatorFactorIO.FactDataId/IRubricatorFactorIO.ValueId, то результирующая матрица показателей IRubricatorExecuteResult.Factors будет иметь пустые значения, а результирующая матрица значений IRubricatorExecuteResult.Values будет содержать значения показателей (значения атрибута VL). Сами значения можно будет определить с помощью свойства IMatrixModelIterator.Value.

Если заданы свойства IRubricatorFactorIO.FactDataId/IRubricatorFactorIO.ValueId, то после расчёта в каждой ячейке результирующих матриц будет доступен набор значений указываемых атрибутов. Свойство ValueCount вернёт количество значений атрибутов в каждой ячейке матрицы (соответствует количеству атрибутов, указываемых в свойствах IRubricatorFactorIO.FactDataId/IRubricatorFactorIO.ValueId). Значение каждого атрибута можно будет получить с помощью свойства Values.

Пример Fore

Для выполнения примера предполагается наличие в репозитории базы данных временных рядов с идентификатором «TSDB».

Sub UserProc;
Var
    MB: IMetabase;
    RubInst: IRubricatorInstance;
    Cube: ICubeInstance;
    Dest: ICubeInstanceDestination;
    Exec: ICubeInstanceDestinationExecutor;
    Matr, DataMatr: IMatrix;
    Iterator: IMatrixIterator;
    i: Integer;
Begin
    MB := MetabaseClass.Active;
    RubInst := MB.ItemById("TSDB").Open(Null) As IRubricatorInstance;
    Cube := RubInst As ICubeInstance;
    Dest := Cube.Destinations.DefaultDestination;
    Exec := Dest.CreateExecutor;
    //Атрибуты показателей
    (Exec As IRubricatorFactorIO).FactDataId := "FACTOR;MNEMO";
    //Атрибуты наблюдения
    (Exec As IRubricatorFactorIO).ValueId := "FACTOR;VL";
    Exec.PrepareExecute(Null);
    Exec.PerformExecute;
    Matr := Exec.Matrix;
    //Матрица показателей
    Debug.WriteLine("Информация о показателях:");
    DataMatr := (CubeClass.ExecuteResult(Matr) As IRubricatorExecuteResult).Factors;
    Iterator := DataMatr.CreateIterator;
    Iterator.Move(IteratorDirection.First);
    While Iterator.Valid Do
        For i := 0 To Matr.ValueCount - 1 Do
            Select Case i
                Case 0: Debug.Write("Показатель: ");
                Case 1: Debug.Write(" Мнемоника: ");
            End Select;
            Debug.Write(Iterator.Values(i) + ".");
        End For;
        Debug.WriteLine("");
        Iterator.Move(IteratorDirection.Next);
    End While;
    //Матрица значений
    Debug.WriteLine("Информация о значениях показателей:");
    DataMatr := (CubeClass.ExecuteResult(Matr) As IRubricatorExecuteResult).Values;
    Iterator := DataMatr.CreateIterator;
    Iterator.Move(IteratorDirection.First);
    While Iterator.Valid Do
            For i := 0 To Matr.ValueCount - 1 Do
            Select Case i
                Case 0: Debug.Write("Показатель: ");
                Case 1: Debug.Write(" Значение: ");
            End Select;
            Debug.Write(Iterator.Values(i) + ".");
        End For;
        Debug.WriteLine("");
        Iterator.Move(IteratorDirection.Next);
    End While;
End Sub UserProc;

При выполнении примера будет осуществлён расчет базы данных временных рядов. После расчета будут получены матрица показателей и матрица значений. Для каждого показателя при расчёте извлекается ключ (значения атрибута FACTOR) и мнемоника (значение атрибута MNEMO). В каждой ячейке матрицы значений будет доступен ключ показателя (значения атрибута FACTOR) и само значение (значения атрибута VL). Все значения будут выведены в консоль среды разработки.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Cubes;
Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Matrix;
Imports Prognoz.Platform.Interop.Metabase;

Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    RubInst: IRubricatorInstance;
    Cube: ICubeInstance;
    CubeClassCls: CubeClass = New CubeClassClass();
    Dest: ICubeInstanceDestination;
    Exec: ICubeInstanceDestinationExecutor;
    Matr, DataMatr: IMatrix;
    Iterator: IMatrixIterator;
    i: Integer;
Begin
    MB := Params.Metabase;
    RubInst := MB.ItemById["TSDB"].Open(Null) As IRubricatorInstance;
    Cube := RubInst As ICubeInstance;
    Dest := Cube.Destinations.DefaultDestination;
    Exec := Dest.CreateExecutor();
    //Атрибуты показателей
    (Exec As IRubricatorFactorIO).FactDataId := "FACTOR;DL;MNEMO";
    //Атрибуты наблюдения
    (Exec As IRubricatorFactorIO).ValueId := "FACTOR;VL";
    Exec.PrepareExecute(Null);
    Exec.PerformExecute(False);
    Matr := Exec.Matrix;
    //Матрица показателей
    System.Diagnostics.Debug.WriteLine("Информация о показателях:");
    DataMatr := (CubeClassCls.ExecuteResult[Matr] As IRubricatorExecuteResult).Factors;
    Iterator := DataMatr.CreateIterator();
    Iterator.Move(IteratorDirection.itdFirst);
    While Iterator.Valid Do
        For i := 0 To Matr.ValueCount - 1 Do
            Select Case i
                Case 0: System.Diagnostics.Debug.Write("Показатель: ");
                Case 1: System.Diagnostics.Debug.Write(" Мнемоника: ");
            End Select;
            System.Diagnostics.Debug.Write(Iterator.Values[i] + ".");
        End For;
        System.Diagnostics.Debug.WriteLine("");
        Iterator.Move(IteratorDirection.itdNext);
    End While;
    //Матрица значений
    System.Diagnostics.Debug.WriteLine("Информация о значениях показателей:");
    DataMatr := (CubeClassCls.ExecuteResult[Matr] As IRubricatorExecuteResult).Values;
    Iterator := DataMatr.CreateIterator();
    Iterator.Move(IteratorDirection.itdFirst);
    While Iterator.Valid Do
            For i := 0 To Matr.ValueCount - 1 Do
            Select Case i
                Case 0: System.Diagnostics.Debug.Write("Показатель: ");
                Case 1: System.Diagnostics.Debug.Write(" Значение: ");
            End Select;
            System.Diagnostics.Debug.Write(Iterator.Values[i] + ".");
        End For;
        System.Diagnostics.Debug.WriteLine("");
        Iterator.Move(IteratorDirection.itdNext);
    End While;
End Sub;

См. также:

IMatrixIterator