IEaxMap.IndicatorElement

Синтаксис Fore

IndicatorElement(IndicatorType: EaxMapIndicatorType): Integer;

Синтаксис Fore.NET

IndicatorElement(IndicatorType: Prognoz.Platform.Interop.Express.EaxMapIndicatorType): Integer;

Параметры

IndicatorType. Тип показателя карты, который необходимо сопоставить с элементом измерения источника данных.

Описание

Свойство IndicatorElement определяет индекс элемента измерения, значения по которому будут использованы в указанном показателе карты.

Данное свойство позволяет сопоставить показателю карты элемент измерения показателей, данные по которого будут использованы в качестве соответствующей динамической характеристики территорий. Измерение показателей задается в свойстве IndicatorsDim.

Пример Fore

Для выполнения примера предполагается наличие экспресс-отчета с идентификатором «EXPRESS_REPORT». Измерения источника данных экспресс-отчета основаны на следующих справочниках:

Справочник с идентификатором «D_Indicators», содержащий два элемента. Данные, хранящиеся по этим элементам, будут определять динамику карты;
Территориальный справочник с идентификатором «D_Map»;
Календарный справочник с идентификатором «Calendar».

Sub UserProc;
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, TDim, TimeDim: IDimSelection;
    EMap: IEaxMap;
Begin
    MB := MetabaseClass.Active;
    Eax := MB.ItemById("EXPRESS_REPORT").Edit As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Поиск измерений
    IDim := Selection.FindById("D_Indicators");
    TDim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Сброс расположения измерений
    Pivot.LeftHeader.Clear;
    Pivot.TopHeader.Clear;
    //Отметим элементы первого уровня календаря
    TimeDim.SelectSiblings(0);
    //Настройка параметров карты
    EMap := Eax.Map;
    //Активация карты
    EMap.Active := True;
    //Настройка измерений
    EMap.IndicatorsDim := IDim.Dimension;
    EMap.TerritoriesDim := TDim.Dimension;
    //Определяем элементы, по которым будут браться значения для измерений карты
    EMap.IndicatorElement(EaxMapIndicatorType.Color) := 0;
    EMap.IndicatorElement(EaxMapIndicatorType.Depth) := 1;
    //Сохранение изменений
    (Eax As IMetabaseObject).Save;
End Sub UserProc;

При выполнении примера будет осуществлена настройка экспресс-отчета для работы картой. В экспресс-отчете будет установлено необходимое расположение измерений, по измерениям будет установлена необходимая отметка. Для карты будут указаны измерения и определены элементы, по которым будут браться значения для динамического изменения карты.

Пример Fore.NET

Справочник с идентификатором «D_Indicators», содержащий два элемента. Данные, хранящиеся по этим элементам, будут определять динамику карты;
Территориальный справочник с идентификатором «D_Map»;
Календарный справочник с идентификатором «Calendar».

Указанный пример является точкой входа для .NET сборки.

Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Pivot;

Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, TDim, TimeDim: IDimSelection;
    EMap: IEaxMap;
Begin
    MB := Params.Metabase;
    Eax := MB.ItemById["EXPRESS_REPORT"].Edit() As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Поиск измерений
    IDim := Selection.FindById("D_Indicators");
    TDim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Сброс расположения измерений
    Pivot.LeftHeader.Clear();
    Pivot.TopHeader.Clear();
    //Отметим элементы первого уровня календаря
    TimeDim.SelectSiblings(0);
    //Настройка параметров карты
    EMap := Eax.Map;
    //Активация карты
    EMap.Active := True;
    //Настройка измерений
    EMap.IndicatorsDim := IDim.Dimension;
    EMap.TerritoriesDim := TDim.Dimension;
    //Определяем элементы, по которым будут браться значения для измерений карты
    EMap.IndicatorElement[EaxMapIndicatorType.emitColor] := 0;
    EMap.IndicatorElement[EaxMapIndicatorType.emitDepth] := 1;
    //Сохранение изменений
    (Eax As IMetabaseObject).Save();
End Sub;

См. также:

IEaxMap