IEaxDataAreaHierarchy.HierarchySettings

Синтаксис Fore

HierarchySettings: IEaxHierarchySettings;

Синтаксис Fore.NET

HierarchySettings: Prognoz.Platform.Interop.Express.EaxHierarchySettings;

Описание

Свойство HierarchySettings определяет настройки альтернативной иерархии.

Комментарии

Для создания настроек используйте класс EaxHierarchySettings.

Пример Fore

Для выполнения примера в репозитории предполагается наличие экспресс-отчета с идентификатором «EXPRESS_HIE», содержащего пользовательскую альтернативную иерархию.

Добавьте ссылки на системные сборки: Dimensions, Express, Metabase, Tab.

Sub UserProc;
Var
    MB: IMetabase;
    Express: IEaxAnalyzer;
    Hier: IEaxDataAreaHierarchy;
    HierSett: IEaxHierarchySettings;
    DimSel: IDimSelection;
    DimEl: String;
    CellStyle: IEaxDataAreaCellStyle;
Begin
    // Получаем текущий репозиторий
    MB := MetabaseClass.Active;
    // Получаем экспресс-отчет
    Express := MB.ItemById("EXPRESS_HIE").Edit As IEaxAnalyzer;
    // Получаем альтернативную иерархию
    Hier := Express.DataArea.Hierarchies.Item(0);
    // Создаем настройки альтернативной иерархии
    HierSett := New EaxHierarchySettings.Create;
    Hier.HierarchySettings := HierSett;
    // Изменяем выравнивание заголовка для первого элемента альтернативной иерархии
    DimSel := Hier.Selection;
    DimSel.SelectAll;
    DimEl := DimSel.Dimension.Elements.Id(DimSel.Element(0));
    CellStyle := New EaxDataAreaCellStyle.Create;
    CellStyle.Header.HorizontalAlignment := TabFormatAlignment.Center;
    HierSett.CellStyle(DimEl) := CellStyle;
    // Сохраняем изменения
    (Express As IMetabaseObject).Save;
End Sub UserProc;

В результате выполнения примера будет изменено оформление заголовка для первого элемента альтернативной иерархии.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Tab;
…
Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Express: IEaxAnalyzer;
    Hier: IEaxDataAreaHierarchy;
    HierSett: EaxHierarchySettings;
    DimSel: IDimSelection;
    DimEl: String;
    CellStyle: EaxDataAreaCellStyle;
Begin
    // Получаем текущий репозиторий
    MB := Params.Metabase;
    // Получаем экспресс-отчет
    Express := MB.ItemById["EXPRESS_HIE"].Edit() As IEaxAnalyzer;
    // Получаем альтернативную иерархию
    Hier := Express.DataArea.Hierarchies.Item[0];
    // Создаем настройки альтернативной иерархии
    HierSett := New EaxHierarchySettings.Create();
    Hier.HierarchySettings := HierSett;
    // Изменяем выравнивание заголовка для первого элемента альтернативной иерархии
    DimSel := Hier.Selection;
    DimSel.SelectAll();
    DimEl := DimSel.Dimension.Elements.Id[DimSel.Element[0]];
    CellStyle := New EaxDataAreaCellStyle.Create();
    CellStyle.Header.HorizontalAlignment := TabFormatAlignment.tfaCenter;
    HierSett.CellStyle[DimEl] := CellStyle;
    // Сохраняем изменения
    (Express As IMetabaseObject).Save();
End Sub;

См. также:

IEaxDataAreaHierarchy