IEaxAnalyzeCore.DrillSerie

Синтаксис Fore

DrillSerie(Serie: IChartSerie): IEaxDrillSerieResult;

Синтаксис Fore.NET

DrillSerie(Serie: Prognoz.Platform.Interop.Chart.IChartSerie): Prognoz.Platform.Interop.Express.IEaxDrillSerieResult;

Параметры

Serie. Ряд данных.

Описание

Метод DrillSerie возвращает информацию о привязке ряда к данным.

Комментарии

Для получения параметров ряда, для которого был выполнен метод DrillSerie, используйте свойство IEaxDrillSerieResult.Serie.

Пример Fore

Для выполнения примера предполагается наличие формы, содержащей компонент Button с наименованием «Button1», компонент ChartBox с наименованием «ChartBox1» и компонент UiErAnalyzer с наименованием «UiErAnalyzer1», являющийся источником данных для компонента «ChartBox1».
В качестве источника данных для компонента «UiErAnalyzer1» укажите экспресс-отчёт с диаграммой, содержащей хотя бы один ряд с данными. Установите для компонента «UiErAnalyzer1» свойство Active = True.

Добавьте ссылки на системные сборки Chart, Dimensions.

Процедура является обработчиком события OnClick для компонента «Button1».

Sub Button1OnClick(Sender: Object; Args: IMouseEventArgs);
Var
    Expr: IEaxAnalyzer;
    Serie: IChartSerie;
    DrillSerie: IEaxDrillSerieResult;
    DimSelection: IDimSelectionSet;
    CountSel, i: Integer;
Begin
    Expr := UiErAnalyzer1.Instance As IEaxAnalyzer;
    Serie := Expr.Chart.Chart.Series.Item(0);
    DrillSerie := Expr.DrillSerie(Serie);
    If DrillSerie <> Null Then
        DimSelection := DrillSerie.Selection;
        Debug.WriteLine("Элементы в отметке:");
        CountSel := DimSelection.Count;
        For i := 0 To CountSel - 1 Do
            Debug.WriteLine("• " + DimSelection.Item(i).ToString("NAME", ", ", True));
        End For;
    End If;
End Sub Button1OnClick;

При нажатии на кнопку в окно консоли для первого ряда данных будет выведен список элементов, содержащихся в отметке по всем измерениям.

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore. Вместо компонентов Fore используйте их Fore.NET аналоги.

Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Chart;
Imports Prognoz.Platform.Interop.Dimensions;
…
Private Sub button1_Click(sender: System.Object; e: System.EventArgs);
Var
    Expr: IEaxAnalyzer;
    Serie: IChartSerie;
    DrillSerie: IEaxDrillSerieResult;
    DimSelection: IDimSelectionSet;
    DimSel: IDimSelection;
    CountSel, i: Integer;
Begin
    Expr := UiErAnalyzerNet1.ErAnalyzer.Instance As IEaxAnalyzer;
    Serie := Expr.Chart.Chart.Series.Item[0];
    DrillSerie := Expr.DrillSerie(Serie);
    If DrillSerie <> Null Then
        DimSelection := DrillSerie.Selection;
        System.Diagnostics.Debug.WriteLine("Элементы в отметке:");
        CountSel := DimSelection.Count;
        For i := 0 To CountSel - 1 Do
            DimSel := DimSelection.Item[i];
            System.Diagnostics.Debug.WriteLine("• " + DimSel.ToString("NAME", ", ", True));
        End For;
    End If;
End Sub;

См. также:

IEaxAnalyzeCore