ICubeSerializer.SaveToFile

Синтаксис Fore

SaveToFile(FileName: String; CubeInstance: ICubeInstance): ICubeSerialInstance;

Синтаксис Fore.NET

SaveToFile(FileName: String; CubeInstance: Prognoz.Platform.Interop.Cubes.ICubeInstance): Prognoz.Platform.Interop.Cubes.ICubeSerialInstance;

Параметры

FileName. Файл, в который сохраняется структура куба и данные куба. Если файл существует, то он автоматически перезаписывается.

CubeInstance. Отстроенный куб, который необходимо сохранить в файл.

Описание

Метод SaveToFile создает файл и инициализирует процесс сохранения куба в файл. Для сохранения данных необходимо после инициализации вызвать метод Save.

Пример Fore

Для выполнения примера предполагается наличие в репозитории куба с идентификатором "Cube_1".

Sub Main;
Var
    MB: IMetabase;
    Des: IMetabaseObjectDescriptor;
    CubInst: ICubeInstance;
    CubeDist: ICubeInstanceDestination;
    CubS: ICubeSerializer;
    CubSIns: ICubeSerialInstance;
    DimSS: IDimSelectionSet;
    DimS: IDimSelection;
Begin
    MB := MetabaseClass.Active;
    CubS := New CubeSerializer.Create As ICubeSerializer;
    Des := MB.ItemById("Cube_1");
    CubInst := Des.Open(Null) As ICubeInstance;
    CubeDist := CubInst.Destinations.DefaultDestination;
    CubSIns := CubS.SaveToFile("c:\cub.ppcube", CubInst);
    DimSS := CubeDist.CreateDimSelectionSet;
    For Each DimS In DimSS Do
        DimS.SelectAll;
    End For;
    CubSIns.Save(CubeDist, DimSS, 0);
End Sub Main;

После выполнения примера куб со всеми данными будет сохранен в файл "cub.ppcube".

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore.

Imports Prognoz.Platform.Interop.Cubes;
Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Metabase;

Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Des: IMetabaseObjectDescriptor;
    CubInst: ICubeInstance;
    CubeDist: ICubeInstanceDestination;
    CubS: CubeSerializer = New CubeSerializerClass();
    CubSIns: ICubeSerialInstance;
    DimSS: IDimSelectionSet;
    DimS: IDimSelection;
Begin
    MB := Params.Metabase;
    Des := MB.ItemById["Cube_1"];
    CubInst := Des.Open(Null) As ICubeInstance;
    CubeDist := CubInst.Destinations.DefaultDestination;
    CubSIns := CubS.SaveToFile("c:\cub.ppcube", CubInst);
    DimSS := CubeDist.CreateDimSelectionSet();
    For Each DimS In DimSS Do
        DimS.SelectAll();
    End For;
    CubSIns.Save(CubeDist, DimSS, 0);
End Sub;

См. также:

ICubeSerializer