IAdhocReportExportSource.TitleSettings

Синтаксис Fore

TitleSettings: IAdhocReportExportSourceTitle;

Синтаксис Fore.NET

Отсутствует;

Описание

Свойство TitleSettings возвращает параметры экспорта заголовка блока.

Комментарии

По умолчанию параметры не заданы и блоки экспортируются без заголовков.

Пример Fore

Для выполнения примера в репозитории предполагается наличие аналитической панели с идентификатором «DASHBOARD». Добавьте ссылки на системные сборки «Adhoc», «Drawing», «Metabase».

Sub UserProc;
Var
    mb: IMetabase;
    repObj: IMetabaseObject;
    report: IAdhocReport;
    repExporter: IAdhocReportExporter;
    reportDS: IAdhocDataSourceObjects;
    expReportDS: IAdhocReportExportSources;
    i: Integer;
    expSrc: IAdhocReportExportSource;
    expSrcTitle: IAdhocReportExportSourceTitle;
Begin
    mb := MetabaseClass.Active;
    // Получаем аналитическую панель
    repObj := mb.ItemById("DASHBOARD").Edit;
    report := repObj As IAdhocReport;
    // Создаем объект для экспорта панели
    repExporter := New AdhocReportExporter.Create;
    repExporter.AdhocReport := report;
    // Получаем блоки аналитической панели
    reportDS := report.DataSourceObjects;
    // Получаем экспортируемые блоки
    expReportDS := repExporter.Sources;
    // Добавляем экспортируемые блоки
    For i := 0 To reportDS.Count - 1 Do
        expSrc := expReportDS.Add(reportDS.Item(i));
        // Настраиваем параметры заголовка экспортируемого блока
        expSrcTitle := expSrc.TitleSettings;
        expSrcTitle.Text := "Заголовок блока №" + (i + 1).ToString;
        expSrcTitle.Font := New GxFont.Create("Courier", 12);
        expSrcTitle.Color := New GxColor.CreateRGB(0, 0, 255);
        expSrcTitle.HorizontalAlignment := AdhocHorizontalAlignment.Right;
        Debug.WriteLine("Настроен заголовок для блока с идентификатором '" + expSrc.DataSource.Id + "'");
    End For;
    Debug.WriteLine("Общее количество настроенных заголовков блоков: " + expReportDS.Count.ToString);
    // Выполняем экспорт
    repExporter.ExportToFile("C:\Dashboard.rtf", "rtf");
    // Сохраняем изменения
    repObj.Save;
End Sub UserProc;

Результат выполнения примера: для всех блоков аналитической панели, имеющих источник данных, настроены параметры экспорта заголовка. Экспорт выполнен в файл «C:\Dashboard.rtf».

См. также:

IAdhocReportExportSource