IChartCorridor.Background

Синтаксис Fore

IChartCorridor.Background: IChartBackgroundInfo;

Синтаксис Fore.NET

IChartCorridor.Background: Prognoz.Platform.Interop.Chart.ChartBackgroundInfo;

Описание

Свойство Background определяет параметры заливки коридора диаграммы.

Пример Fore

Для выполнения примера создайте форму, добавьте на нее кнопку с наименованием «Button1», компонент ChartBox с наименованием «ChartBox1», компонент UiChart с наименованием «UiChart1», укажите «UiChart1» в качестве источника компонента ChartBox, у компонента UiChart укажите значения свойств PointCount и SerieCount, в инспекторе сборок модуля добавьте ссылки на системные сборки Chart, MathFin и Drawing.

Class OBJ761Form: Form
    Button1: Button;
    ChartBox1: ChartBox;
    UiChart1: UiChart;

    Sub OBJ761FormOnShow(Sender: Object; Args: IEventArgs);
        Var
            Chart: IChart;
    Begin
        Chart := UiChart1.Chart;
        Chart.Type := ChartType.Lines;
    End Sub OBJ761FormOnShow;

    Sub UiChart1OnGetDataValue(Sender: Object; Args: IUiChartGetDataValueEventArgs);
    Begin
        Args.Result := True;
        Args.Value := Math.Rand;
    End Sub UiChart1OnGetDataValue;

    Sub Button1OnClick(Sender: Object; Args: IMouseEventArgs);
    Var
        Corridor: IChartCorridor;
        BackgroundInfo: IChartBackgroundInfo;
        i: Integer;
    Begin
        i := UiChart1.Chart.Corridors.Add(0, 2);
        Corridor := UiChart1.Chart.Corridors.Item(i);
        BackgroundInfo := New ChartBackgroundInfo.Create;
        BackgroundInfo.Type := ChartBackgroundType.Gradient;
        BackgroundInfo.Color := New GxColor.CreateARGB(255, 245, 120, 255);
        Corridor.Background := BackgroundInfo;
    End Sub Button1OnClick;

End Class OBJ761Form;

При нажатии на кнопку «Button1» заливка коридора станет градиентной с использованием сиреневого цвета.

Пример Fore.NET

Для выполнения примера создайте .NET форму, добавьте на нее кнопку с наименованием «Button1», компонент ChartBoxNet с наименованием «ChartBoxNet1», компонент uiChartNet с наименованием «UiChartNet1», укажите «UiChartNet1» в качестве источника компонента ChartBoxNet, в инспекторе сборок модуля добавьте ссылки на системные сборки Chart, MathFin и Drawing.

Imports System;
Imports System.Collections.Generic;
Imports System.ComponentModel;
Imports System.Data;
Imports System.Drawing;
Imports System.Text;
Imports System.Windows.Forms;
Imports Prognoz.Platform.Forms.Net;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Chart;
Imports Prognoz.Platform.Interop.MathFin;
Imports Prognoz.Platform.Interop.Drawing;

Public Partial Class OBJ765Form: Prognoz.Platform.Forms.Net.ForeNetForm
    Public Constructor OBJ765Form();
    Begin
        InitializeComponent();
    End Constructor;

    Private Sub uiChartNet1_OnGetDataValue(Sender: System.Object; Args: Prognoz.Platform.Interop.Chart.UiChartGetDataValueEventArgs);
    Var
        Math: Prognoz.Platform.Interop.MathFin.Math = New MathClass();
    Begin
        Args.Result := True;
        Args.Value := Math.Rand();
    End Sub;

    Private Sub OBJ765Form_Shown(sender: System.Object; e: System.EventArgs);
    Var
        Chart: IChart;
    Begin
        Chart := ChartBoxNet1.CtrlBox.Chart;
        uiChartNet1.PointCount := 5;
        uiChartNet1.SerieCount := 4
    End Sub;

    Private Sub button1_Click(sender: System.Object; e: System.EventArgs);
    Var
        Corridor: IChartCorridor;
        Background: ChartBackgroundInfo;
        i: Integer;
        c: GxColorClass_2 = New GxColorClass_2();
    Begin
        i := UiChartNet1.ChartUi.Chart.Corridors.Add[0, 2];
        Corridor := UiChartNet1.ChartUi.Chart.Corridors.Item[i];
        Background := New ChartBackgroundInfoClass();
        Background.Type := ChartBackgroundType.cbtGradient;
        c.CreateARGB(255, 245, 120, 255);
        Background.Color := c;
        Corridor.Background := Background;
    End Sub;
End Class;