IVZControlStyle.Background

Синтаксис Fore

Background: IGxBrush;

Синтаксис Fore.NET

Background: Prognoz.Platform.Interop.Drawing.IGxBrush;

Описание

Свойство Background определяет фон элемента управления.

Пример Fore

Для выполнения примера в репозитории необходимо наличие экспресс-отчета с идентификатором «EXPRESS_REPORT», в котором содержится пузырьковое дерево. Временная шкала пузырькового дерева выглядит так, как показано на странице описания интерфейса IVZBubbleTree. Установим новые значения для свойств временной шкалы: фон, граница, шрифт, цвет шрифта, отступы, поля и цвет теней.

Добавьте ссылки на системные сборки: Metabase, Express, Drawing, Visualizators. Указанная процедура должна вызываться из точки входа Main.

Sub UserProc;
Var
    Metabase: IMetabase; // Репозиторий
    EaxAnalyzer: IEaxAnalyzer; // Экспресс-отчёт
    BubbleTree: IVZBubbleTree; // Пузырьковое дерево
    Timeline: IVZTimeLine; // Временная шкала
    Style: IVZControlStyle; // Стиль временной шкалы
Begin
    // Получим объект репозитория
    Metabase := MetabaseClass.Active;
    // Получим объект экспресс-отчёта
    EaxAnalyzer := Metabase.ItemById("EXPRESS_REPORT").Edit As IEaxAnalyzer;
    // Получим пузырьковое дерево
    BubbleTree := EaxAnalyzer.BubbleTree.BubbleTree;
    // Получим временную шкалу
    Timeline := BubbleTree.TimeLine;
    // Получим стиль временной шкалы
    Style := Timeline.Style;
    // Установим новый фон
    Style.Background := New GxSolidBrush.Create(New GxColor.CreateRGB(206, 157, 182));
    // Установим новый цвет границы
    Style.BorderPen := New GxPen.CreateSolid(New GxColor.CreateRGB(167, 84, 125), 2);
    // Установим радиус скругления границы
    Style.BorderRadius := 1;
    // Установим новый шрифт
    Style.Font := New GxFont.Create("Tahoma", 15);
    // Установим новый цвет шрифта
    Style.FontColor := New GxColor.CreateRGB(0, 0, 0);
    // Установим цвет теней
    Style.FontShadowColor := New GxColor.CreateRGB(255, 0, 0);
    // Установим отступы элемента
    Style.Margin := New GxRectF.Create(15, 15, 15, 15);
    // Установим поля элемента
    Style.Padding := New GxRectF.Create(10, 10, 10, 10);
    // Установим цвет теней
    Style.ShadowColor := New GxColor.CreateRGB(255, 0, 0);
    // Установим измененный стиль
    Timeline.Style := Style;
    // Установим измененную временную шкалу
    BubbleTree.TimeLine := Timeline;
    // Сохраним изменения в экспресс-отчёте
    (EaxAnalyzer As IMetabaseObject).Save;
End Sub UserProc;

После выполнения примера в экспресс-отчёте будут изменены свойства временной шкалы пузырькового дерева: фон, граница, шрифт, цвет шрифта, отступы, поля и цвет теней:

Пример Fore.NET

Необходимые требования и результат выполнения примера Fore.NET совпадают с примером Fore. Вместо компонентов Fore используйте их Fore.NET аналоги.

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Drawing;
Imports Prognoz.Platform.Interop.Visualizators;
…
Public Shared Sub Main(Params: StartParams);
Var
    Metabase: IMetabase; // Репозиторий
    EaxAnalyzer: IEaxAnalyzer; // Экспресс-отчёт
    BubbleTree: IVZBubbleTree; // Пузырьковое дерево
    Timeline: IVZTimeLine; // Временная шкала
    Style: IVZControlStyle; // Стиль временной шкалы
    BackgroundBrush: GxSolidBrush; // Кисть фоновой заливки
    BackgroundColor: GxColor; // Цвет фона
    BorderPen: GxPen; // Стиль рамки
    BorderColor: GxColor; // Цвет рамки
    Font: GxFont; // Шрифт
    FontColor: GxColor; // Цвет шрифта
    Margin: GxRectF; // Отступы элемента
    Padding: GxRectF; // Поля элемента
    ShadowColor: GxColor; // Цвет теней
Begin
    // Получим объект репозитория
    Metabase := Params.Metabase;
    // Получим объект экспресс-отчёта
    EaxAnalyzer := Metabase.ItemById["EXPRESS_REPORT"].Edit() As IEaxAnalyzer;
    // Получим пузырьковое дерево
    BubbleTree := EaxAnalyzer.BubbleTree.BubbleTree;
    // Получим временную шкалу
    Timeline := BubbleTree.TimeLine;
    // Получим стиль временной шкалы
    Style := Timeline.Style;
    // Установим новый фон
    BackgroundColor := New GxColor();
    BackgroundColor.CreateRGB(206, 157, 182);
    BackgroundBrush := New GxSolidBrush();
    BackgroundBrush.Create(BackgroundColor);
    Style.Background := BackgroundBrush;
    // Установим новый цвет границы
    BorderColor := New GxColor();
    BorderColor.CreateRGB(167, 84, 125);
    BorderPen := New GxPen();
    BorderPen.CreateSolid(BorderColor, 2);
    Style.BorderPen := BorderPen;
    // Установим сглаживание границы
    Style.BorderRadius := 10;
    // Установим радиус скругления границы
    Style.BorderRadius := 1;
    // Установим новый шрифт
    Font := New GxFont();
    Font.Create("Tahoma", 15, GxFontStyle.gfsRegular, GxUnit.guInch);
    Style.Font := Font;
    // Установим новый цвет шрифта
    FontColor := New GxColor();
    FontColor.CreateRGB(0, 0, 0);
    Style.FontColor := FontColor;
    // Установим отступы элемента
    Margin := New GxRectF();
    Margin.Create(15, 15, 15, 15);
    Style.Margin := Margin;
    // Установим поля элемента
    Padding := New GxRectF();
    Padding.Create(10, 10, 10, 10);
    Style.Padding := Padding;
    // Установим цвет теней
    ShadowColor := New GxColor();
    ShadowColor.CreateRGB(255, 0, 0);
    Style.ShadowColor := ShadowColor;
    // Сохраним изменения в экспресс-отчёте
    (EaxAnalyzer As IMetabaseObject).Save();
End Sub;

См. также:

IVZControlStyle