PPStat: IUnitRootTestStatistic;
PPStat: Prognoz.Platform.Interop.Stat.IUnitRootTestStatistic;
The PPStat property returns value of the Phillips-Perron test statistics.
To get the value of adjusted residual variance, use the ISmPhillipsPerronTest.F0 property.
To execute the example, add a link to the Stat system assembly.
Sub UserProc;
Var
PP: SmPhillipsPerronTest;
SumStat: ISummaryStatistics;
PPStat: IUnitRootTestStatistic;
can: Array[43] Of Double;
i, res: Integer;
Begin
PP := New SmPhillipsPerronTest.Create;
// Set values for variables
can[0] := 6209; can[1] := 6385; can[2] := 6752; can[3] := Double.Nan; can[4] := 6495;
can[5] := Double.Nan; can[6] := 7349; can[7] := 7213; can[8] := 7061; can[9] := 7180;
can[10] := 7132; can[11] := 7137; can[12] := 7473; can[13] := 7722; can[14] := 8088;
can[15] := 8516; can[16] := 8941; can[17] := 9064; can[18] := 9380; can[19] := 9746;
can[20] := 9907; can[21] := 10333; can[22] := 10863; can[23] := 11693; can[24] := 12242;
can[25] := 12227; can[26] := 12910; can[27] := 13049; can[28] := 13384; can[29] := 14036;
can[30] := 14242; can[31] := 14704; can[32] := 13802; can[33] := 14197; can[34] := 15010;
can[35] := 15589; can[36] := 15932; can[37] := 16631; can[38] := 17394; can[39] := 17758;
can[40] := 17308; can[41] := 16444; can[42] := 16413;
//Select tested series
PP.Serie.Value := can;
// Type of tested series
PP.TestedSeries := ADFTestedSeriesType.Level;
// Method of missing data treatment
PP.MissingData.Method := MissingDataMethod.LinTrend;
// Model type
PP.Equation := ADFEquationType.Constant;
// Method of calculation of adjusted residuals variance
PP.F0SpectrumEstimation := F0SpectrumEstimationType.BartlettKernel;
// Autoregression order
PP.AutoRegressionOrder := 9;
// Sample period
PP.ModelPeriod.FirstPoint := 1;
PP.ModelPeriod.LastPoint := 43;
res := PP.Execute;
For i := 0 To PP.WarningsCount - 1 Do
Debug.WriteLine(PP.Warnings[i]);
End For;
PPStat := PP.PPStat;
SumStat := PP.SummaryStatistics;
If res = 0 Then
// display statistical values
Debug.WriteLine("===Phillips-Perron test statistics===");
Debug.WriteLine("Statistics value: " + PPStat.Statistics.ToString);
Debug.WriteLine("Probability value: " + PPStat.Probability.ToString);
Debug.WriteLine("Critical values: ");
Debug.Indent;
For i := 0 To PPStat.CriticalValues.Length - 1 Do
Debug.Write(i.ToString + " ");
Debug.WriteLine(PPStat.CriticalValues[i]);
End For;
Debug.Unindent;
Debug.WriteLine("Adjusted residuals variance: " + PP.F0.ToString);
Debug.WriteLine("Residuals variance: " + PP.S0.ToString);
Debug.WriteLine("===Auxiliary regression===");
Debug.WriteLine("Auxiliary regression coefficients:");
Debug.Indent;
For i := 0 To PP.ModelCoefficients.Estimate.Length - 1 Do
Debug.WriteLine(PP.ModelCoefficients.Estimate[i]);
End For;
Debug.Unindent;
Debug.WriteLine("Descriptive characteristics of auxiliary regression:");
Debug.Indent;
Debug.WriteLine("Fisher statistic: " + SumStat.Fstat.ToString);
Debug.WriteLine("Probability for Fisher statistics: " + SumStat.ProbFstat.ToString);
Debug.Unindent;
Else
Debug.WriteLine(PP.Errors);
End If;
End Sub UserProc;
After executing the example the console window displays calculation results for the Phillips-Perron test.
The requirements and result of the Fore.NET example execution match with those in the Fore example.
Imports Prognoz.Platform.Interop.Stat;
…
Public Shared Sub Main(Params: StartParams);
Var
PP: SmPhillipsPerronTest;
SumStat: ISummaryStatistics;
can: Array[43] Of double;
i, res: integer;
Warnings, CriticalValues, ModelCoefficients: Array;
Begin
PP := New SmPhillipsPerronTestClass.Create();
// Set values for variables
can[0] := 6209; can[1] := 6385; can[2] := 6752; can[3] := Double.Nan; can[4] := 6495;
can[5] := Double.Nan; can[6] := 7349; can[7] := 7213; can[8] := 7061; can[9] := 7180;
can[10] := 7132; can[11] := 7137; can[12] := 7473; can[13] := 7722; can[14] := 8088;
can[15] := 8516; can[16] := 8941; can[17] := 9064; can[18] := 9380; can[19] := 9746;
can[20] := 9907; can[21] := 10333; can[22] := 10863; can[23] := 11693; can[24] := 12242;
can[25] := 12227; can[26] := 12910; can[27] := 13049; can[28] := 13384; can[29] := 14036;
can[30] := 14242; can[31] := 14704; can[32] := 13802; can[33] := 14197; can[34] := 15010;
can[35] := 15589; can[36] := 15932; can[37] := 16631; can[38] := 17394; can[39] := 17758;
can[40] := 17308; can[41] := 16444; can[42] := 16413;
//Select tested series
PP.Serie.Value := can;
// Type of tested series
PP.TestedSeries := ADFTestedSeriesType.adftstLevel;
// Method of missing data treatment
PP.MissingData.Method := MissingDataMethod.mdmLinTrend;
// Model type
PP.Equation := ADFEquationType.adfetConstant;
// Method of calculation of adjusted residuals variance
PP.F0SpectrumEstimation := F0SpectrumEstimationType.f0setBartlettKernel;
// Autoregression order
PP.AutoRegressionOrder := 9;
// Sample period
PP.ModelPeriod.FirstPoint := 1;
PP.ModelPeriod.LastPoint := 43;
res := PP.Execute();
Warnings := PP.Warnings;
For i := 0 To PP.WarningsCount - 1 Do
System.Diagnostics.Debug.WriteLine(Warnings[i]);
End For;
If res = 0 Then
// display statistical values
System.Diagnostics.Debug.WriteLine("===Phillips-Perron test statistics===");
System.Diagnostics.Debug.WriteLine("Statistics value: " + PP.PPStat.Statistics.ToString());
System.Diagnostics.Debug.WriteLine("Probability value: " + PP.PPStat.Probability.ToString());
System.Diagnostics.Debug.WriteLine("Critical values: ");
CriticalValues := PP.PPStat.CriticalValues;
System.Diagnostics.Debug.Indent();
For i := 0 To PP.PPStat.CriticalValues.Length - 1 Do
System.Diagnostics.Debug.Write(i.ToString() + " ");
System.Diagnostics.Debug.WriteLine(CriticalValues[i]);
End For;
System.Diagnostics.Debug.Unindent();
System.Diagnostics.Debug.WriteLine("Adjusted residuals variance: " + PP.F0.ToString());
System.Diagnostics.Debug.WriteLine("Residuals variance: " + PP.S0.ToString());
System.Diagnostics.Debug.WriteLine("===Auxiliary regression===");
System.Diagnostics.Debug.WriteLine("Auxiliary regression coefficients:");
ModelCoefficients := PP.ModelCoefficients.Estimate;
System.Diagnostics.Debug.Indent();
For i := 0 To PP.ModelCoefficients.Estimate.Length - 1 Do
System.Diagnostics.Debug.WriteLine(ModelCoefficients[i]);
End For;
System.Diagnostics.Debug.Unindent();
System.Diagnostics.Debug.WriteLine("Descriptive characteristics of auxiliary regression:");
SumStat := PP.SummaryStatistics;
System.Diagnostics.Debug.Indent();
System.Diagnostics.Debug.WriteLine("Fisher statistic: " + SumStat.Fstat.ToString());
System.Diagnostics.Debug.WriteLine("Probability for Fisher statistics: " + SumStat.ProbFstat.ToString());
System.Diagnostics.Debug.Unindent();
Else
System.Diagnostics.Debug.WriteLine(PP.Errors);
End If;
End Sub;
See also: