IPPSpeedometerScale.BorderWidth

Fore Syntax

BorderWidth: Double;

Fore.NET Syntax

BorderWidth: double;

Description

The BorderWidth property determines width of scale border.

Comments

The BorderWidth property is relevant if the IPPSpeedometerScale.EnableBorder property is set to True.

Fore Example

Executing the example requires that the repository contains a database with the ADHOC identifier. A dashboard must contain a speedometer.

Add links to the Adhoc, Drawing, Express, Metabase, Speedometer system assemblies.

Sub UserProc;
Var
    Speedometer: IPPSpeedometer;
    MB: IMetabase;
    AdhocReport: IAdhocReport;
    EaxSpeedometer: IEaxSpeedometer;
    Enalyzer: IEaxAnalyzer;
    DsObjs: IAdhocDataSourceObjects;
    Scales: IPPSpeedometerScales;
    Scale: IPPSpeedometerScale;
    SolidBrush: IGxSolidBrush;
    Color: IGxColor;
Begin
    MB := MetabaseClass.Active;
    // Get dashboard
    AdhocReport := MB.ItemById("ADHOC").Edit As IAdhocReport;
    // Get dashboard data sources
    DsObjs := AdhocReport.DataSourceObjects;
    // Get speedometer
    Enalyzer := DsObjs.Item(0).GetSourceObject As IEaxAnalyzer;
    EaxSpeedometer := Enalyzer.Speedometer;
    // Get speedometer parameters
    Speedometer := EaxSpeedometer.Speedometer;
    // Get collection of speedometer scales
    Scales := Speedometer.Scales;
    // Get scale
    Scale := Scales.Item(0);
    // Set up scale border
    Scale.EnableBorder := True;
    // Set up border color
    Color := New GxColor.CreateRGB(255,0,0);
    SolidBrush := New GxSolidBrush.Create(Color);
    Scale.BorderBrush := SolidBrush;
    // Set up border width
    Scale.BorderWidth := 5;
    // Set up style of border rendering
    Scale.BorderStyle := GxDashStyle.Dash;
    // Set up background fill
    Scale.EnableBrush := True;
    // Set up fill color
    Color := New GxColor.CreateRGB(0,255,0);
    SolidBrush := New GxSolidBrush.Create(Color);
    Scale.Background := SolidBrush;
    (Enalyzer As IMetabaseObject).Save;
End Sub UserProc;

After executing the example scale border and background are set up.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.AdHoc;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Speedometer;
Imports Prognoz.Platform.Interop.Drawing;
…
Public Shared Sub Main(Params: StartParams);
Var
    Speedometer: IPPSpeedometer;
    MB: IMetabase;
    AdhocReport: IAdhocReport;
    EaxSpeedometer: IEaxSpeedometer;
    Enalyzer: IEaxAnalyzer;
    DsObjs: IAdhocDataSourceObjects;
    Scales: IPPSpeedometerScales;
    Scale: PPSpeedometerScale;
    SolidBrush: GxSolidBrushClass;
    Color: GxColorClass;
    BrushColor: GxColor;
Begin
    MB := Params.Metabase;
    // Get dashboard
    AdhocReport := MB.ItemById["ADHOC"].Edit() As IAdhocReport;
    // Get dashboard data sources
    DsObjs := AdhocReport.DataSourceObjects;
    // Get speedometer
    Enalyzer := DsObjs.Item[0].GetSourceObject() As IEaxAnalyzer;
    EaxSpeedometer := Enalyzer.Speedometer;
    // Get speedometer parameters
    Speedometer := EaxSpeedometer.Speedometer;
    // Get collection of speedometer scales
    Scales := Speedometer.Scales;
    // Get scale
    Scale := Scales.Item(0);
    // Set up scale border
    Scale.EnableBorder := True;
    // Set up border color
    Color := New GxColorClassClass();
    BrushColor := Color.FromKnownColor(GxKnownColor.clRed);
    SolidBrush := New GxSolidBrushClass();
    SolidBrush.Color := BrushColor;
    Scale.BorderBrush := SolidBrush;
    // Set up border width
    Scale.BorderWidth := 5;
    // Set up style of border rendering
    Scale.BorderStyle := GxDashStyle.gdsDash;
    // Set up background fill
    Scale.EnableBrush := True;
    // Set up fill color
    BrushColor := Color.FromKnownColor(GxKnownColor.clGreen);
    SolidBrush := New GxSolidBrushClass();
    SolidBrush.Color := BrushColor;
    Scale.Background := SolidBrush;
    (Enalyzer As IMetabaseObject).Save();
End Sub;