MovAvgR(Input: ITimeSeries;
Period: IMsPeriod;
[WindowSize: Integer = 5;]
[Casewise: MsCasewise = 0]): Variant;
MovAvgR(Input: Prognoz.Platform.Interop.Ms.ITimeSeries;
Period: Prognoz.Platform.Interop.Ms.IMsPeriod;
WindowSize: integer;
Casewise: Prognoz.Platform.Interop.Ms.MsCasewise;
Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;
Input. Output variable.
Period. Period, at which the method is calculated. If the parameter is set to Null, the method is calculated at the entire time period.
WindowSize. Window size.
Casewise. Missing data treatment method.
Context. Context. The parameter is used only in Fore.NET.
The MovAvgR method transforms data of a variable using the moving average method using the R package.
The moving average method is based on representing a series as a sum of a sufficiently smooth trend and a random component.
Integration with R must be set up in the repository to use this method. For details about integration setup see the How to Set Up Integration with R? section.
Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D identifier calculated by the method of determinate equation and containing at least one input variable must be available in this container.
Integration with R must be set up in the repository. For details about integration setup see the How to Set Up Integration with R? section.
Add links to the Metabase, Ms system assemblies.
Sub ProcAvgR;
Var
Mb: IMetabase;
ModelSpace, ModelObj: IMetabaseObject;
Transf: IMsFormulaTransform;
Formula: IMsFormula;
Model: IMsModel;
Determ: IMsDeterministicTransform;
TransVar: IMsFormulaTransformVariable;
Slice: IMsFormulaTransformSlice;
TermInfo: IMsFormulaTermInfo;
Expr: IExpression;
Begin
// Get repository
Mb := MetabaseClass.Active;
// Get modeling container
ModelSpace := Mb.ItemById("MS").Bind;
// Get model
ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
Model := ModelObj As IMsModel;
// Get model calculation parameters
Transf := Model.Transform;
Formula := Transf.FormulaItem(0);
Determ := Formula.Method As IMsDeterministicTransform;
// Get the first input variable
TransVar := Transf.Inputs.Item(0);
Slice := TransVar.Slices.Item(0);
TermInfo := Transf.CreateTermInfo;
TermInfo.Slice := Slice;
// Set mode of passing variable into calculation
TermInfo.Type := MsFormulaTermType.Pointwise;
// Get model calculation expression
Expr := Determ.Expression;
Expr.References := "Ms";
// Set expression of model calculation
Expr.AsString := "MovAvgR(" + TermInfo.TermInnerText + ", SetPeriod(" +
"""" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 3, MsCasewise.Yes)";
// Check if the expression is correct
If Expr.Valid
// If the expression is set correctly, save the model
Then ModelObj.Save;
// If the expression is incorrect, display a message to the console window
Else Debug.WriteLine("Model is not saved: error in the formula");
End If;
End Sub ProcAvgR;
After executing the example the model transforms the first input variable by moving average method at the period of 2000-2015. The Casewise missing data treatment method is used. Calculation is executed using the R package.
The requirements and result of the Fore.NET example execution match with those in the Fore example.
Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
Mb: IMetabase;
ModelSpace, ModelObj: IMetabaseObject;
Transf: IMsFormulaTransform;
Formula: IMsFormula;
Model: IMsModel;
Determ: IMsDeterministicTransform;
TransVar: IMsFormulaTransformVariable;
Slice: IMsFormulaTransformSlice;
TermInfo: IMsFormulaTermInfo;
Expr: IExpression;
Begin
// Get repository
Mb := Params.Metabase;
// Get modeling container
ModelSpace := Mb.ItemById["MS"].Bind();
// Get model
ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
Model := ModelObj As IMsModel;
// Get model calculation parameters
Transf := Model.Transform;
Formula := Transf.FormulaItem[0];
Determ := Formula.Method As IMsDeterministicTransform;
// Get the first input variable
TransVar := Transf.Inputs.Item[0];
Slice := TransVar.Slices.Item[0];
TermInfo := Transf.CreateTermInfo();
TermInfo.Slice := Slice;
// Set mode of passing variable into calculation
TermInfo.Type := MsFormulaTermType.mfttPointwise;
// Get model calculation expression
Expr := Determ.Expression;
Expr.References := "Ms";
// Set model calculation expression
Expr.AsString := "MovAvgR(" + TermInfo.TermInnerText + ", SetPeriod(" +
"""" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "), 3, MsCasewise.Yes)";
// Check if the expression is correct
If Expr.Valid
// If the expression is set correctly, save the model
Then ModelObj.Save();
// If the expression is incorrect, display a message to the console window
Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in the formula");
End If;
End Sub;
Expression 1:
MovAvgR({Chicago - population[t]}, SetPeriod("01.01.2000", "01.01.2015"), 4, MsCasewise.Yes)
Result: moving average method is applied to the Chicago - population time series, window size is set to four at the period of 2000-2015. The Casewise missing data treatment method is used. Calculation is executed using the R package.
Use: it can be used in formulas of calculated series of time series database and model formulas of modeling container that is a child of the time series database. The calculation is executed without considering missing values.
Expression 2:
MovAvgR(X1, SetPeriod("01.01.1990", "01.01.2015"))
Result: moving average method using the R package is applied to the X1 factor.
Use: it can be used in model formulas of modeling container.
See also:
IModelling | The Calculation Method moving average | Time Series Database: Calculator | Modeling container: Editing Regressor or Formula