IModelling.LevelIndexSeries

Fore Syntax

LevelIndexSeries(TargetFrequency: MsFrequency,
[OutputFrequency: MsFrequency = 0]): Variant;

Fore.NET Syntax

LevelIndexSeries(TargetFrequency: Prognoz.Platform.Interop.Ms.MsFrequency,
[OutputFrequency: Prognoz.Platform.Interop.Ms.MsFrequency = 0]): Object;

Parameters

TargetFrequency. Calendar frequency, which element indexes must be obtained.

OutputFrequency. Calendar frequency of output series.

Description

The LevelIndexSeries method returns the current element index for set calendar frequency.

Comments

For correct calculation, the TargetFrequency calendar frequency must be greater or equal to the calculation frequency.

If the OutputFrequency parameter is set to 0, the output series is created with the current calculation frequency.

Fore Example

Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D_Q identifier that is calculated by the method of determinate equation based on the quarterly data and contains at least one factor is present in this container.

Add links to the Metabase, Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get the model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D_Q", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "iif(LevelIndexSeries(MsFrequency.Annual,MsFrequency.Quarterly)<=2," + TermInfo.TermInnerText + ",0)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If expression is not correct, output message to console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example the formula is changed for the model. For values of the first and second quarters the model will return values of the first factor and for values of the third and fourth quarters it returns zeros.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Ms;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := Params.Metabase;
    // Get modeling container
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Get the model
    ModelObj := Mb.ItemByIdNamespace["MODEL_D_Q", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "iif(LevelIndexSeries(MsFrequency.Annual,MsFrequency.Quarterly)<=2," + TermInfo.TermInnerText + ",0)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save();
        // If expression is not correct, output message to console window
        Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub;

Example of Use in Expressions

Expression 1:

LevelIndexSeries(MsFrequency.Annual)

Calculation period: 01.04.2000-01.09.2002; quarterly calculation frequency. Result: [2, 3, 4, 1, 2, 3, 4, 1, 2, 3].

Use: it can be used in formulas of calculated series of time series database and in formulas of attribute-based models of modeling container.

Expression 2:

iif(levelindexseries(MsFrequency.Annual, MsFrequency.Quarterly) <= 3, X1, X2)

Result: the expression returns values of the X1 factor for values of the first, second and third quarters and values of the X2 factor for the fourth quarter.

Use: it can be used in model variable-based formulas of modeling container.