IModelling.GetValueByDate

Fore Syntax

GetValueByDate(Input: Variant; Date: Variant): Variant;

Fore.NET Syntax

GetValueByDate(Input: Object; Date: Object): Object;

Parameters

Input. The series, which value must be obtained.

Date. The date, for which the value must be obtained.

Description

The GetValueByDate method returns series value for the specific date.

Comments

A constant, parameter or object of the TimeSeries type can be passed as value of the Input parameter; a number, string or parameter can be passed as value of the Date parameter.

Fore Example

Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D identifier calculated by the method of determinate equation and containing at least one input variable must be available in this container.

Add links to the Metabase, Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar_1: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo_1: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get the model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar_1 := Transf.Inputs.Item(0);
    Slice := TransVar_1.Slices.Item(0);
    TermInfo_1 := Transf.CreateTermInfo;
    TermInfo_1.Slice := Slice;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "GetValueByDate(" + TermInfo_1.TermInnerText + ", 2005)*2";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If expression is not correct, output message to console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example a new expression is set for the determinate equation model: the first input variable value for 2005 multiplied by two.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar_1: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo_1: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := Params.Metabase;
    // Get modeling container
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Get the model
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar_1 := Transf.Inputs.Item[0];
    Slice := TransVar_1.Slices.Item[0];
    TermInfo_1 := Transf.CreateTermInfo();
    TermInfo_1.Slice := Slice;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "GetValueByDate(" + TermInfo_1.TermInnerText + ", 2005)*2";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save();
        // If expression is not correct, output message to console window
        Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub;

Example of Use in Expressions

Expression 1:

GetValueByDate({GDP|Anchorage[t]}, 2005)*2

Result: value of the GDP|Anchorage series for 2005 will be multiplied by two.

Use: it can be used in formulas of calculated series of time series database and in formulas of attribute-based models of modeling container.

Expression 2:

GetValueByDate(X1, "2015A")*2

Result: value of the X1 factor for 2015 will be multiplied by two.

Use: it can be used in model variable-based formulas of modeling container.