IModelling.Combine

Fore Syntax

Combine(Forecast: IMsForecast; Period: IMsPeriod): Variant;

Fore.NET Syntax

Combine(Forecast: Prognoz.Platform.Interop.Ms.IMsForecast; Period: Prognoz.Platform.Interop.Ms.IMsPeriod): object;

Parameters

Forecast. Forecasting series.

Period. Data forecasting period.

Description

The Combine method returns the series containing source series data for the sample period and forecasting series data for the forecasting period.

Comments

If sample and forecasting periods are intersected, forecasting data has higher priority. Thus, returned series includes truncated date at sample period and full data at forecasting period.

Fore Example

Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D identifier calculated by the method of determinate equation and containing at least one input variable must be available in this container.

Add links to the Metabase, Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modeling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get the model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Combine(Arima(" + TermInfo.TermInnerText +
        ", Default_, """ + "" + """, """ + "1" + """, 0, Estimate), SetPeriod(" +
        """" + "01.01.2010" + """" + "," + """" + "01.01.2015" + """" +
        "))";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save;
        // If the expression is incorrect, display a message to the console window
        Else Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub UserProc;

After executing the example the model returns a series containing source series data at sample period and containing forecasting series data at specified forecasting period for the ARIMA method.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Ms;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := Params.Metabase;
    // Get modeling container
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Get the model
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "Combine(Arima(" + TermInfo.TermInnerText +
        ", Default_, """ + "" + """, """ + "1" + """, 0, Estimate), SetPeriod(" +
        """" + "01.01.2010" + """" + "," + """" + "01.01.2015" + """" +
        "))";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save();
        // If the expression is incorrect, display a message to the console window
        Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub;

Example of Use in Expressions

Expression 1:

Combine(Arima({GDP|Anchorage[t]}, Default_, "", "1", 0, Estimate), SetPeriod("01.01.2010", "01.01.2015"))

Result: the series containing source series data at sample period and containing forecasting series data at specified forecasting period will be obtained for the ARIMA model.

Use: it can be used in formulas of calculated series of time series database and in formulas of attribute-based models of modeling container.

Expression 2:

Combine(Arima(X1, Default_, "", "1", 0, Estimate), SetPeriod("01.01.2010", "01.01.2015"))

Result: the series containing source series data at sample period and containing forecasting series data at specified forecasting period will be obtained for the ARIMA model.

Use: it can be used in model variable-based formulas of modeling container.