IModelling.CumulativeYTD

Fore Syntax

CumulativeYTD(Input: ITimeSeries;
             [Method: MsCumulativeMethodType = 5;]
             [Period: IMsPeriod = Null;]
             [IgnoreMissing: Boolean = False;]): Variant;

Fore.NET Syntax

CumulativeYTD(Input: ITimeSeries;
             Method: MsCumulativeMethodType;
             Period: IMsPeriod;
             IgnoreMissing: Boolean;
             Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Parameters

Input. Output variable.

Method. Cumulative method.

Period. Period, at which the method is calculated. If the parameter is set to Null, the method is calculated at the entire time period.

IgnoreMissing. Indicates whether empty values are ignored.

Context. Context. The parameter is used only in Fore.NET.

Description

The CumulativeYTD method transforms variable by applying the specified cumulative method to the start of the year.

Comments

Available values of the IgnoreMissing parameter:

True. Calculation does not take into account empty values.
False. Calculation takes into account empty values.

Fore Example

Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D identifier calculated by the method of determinate equation and containing at least one factor must be available in this container.

Add links to the Metabase, Ms system assemblies.

Sub UserProc;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := MetabaseClass.Active;
    // Get modelling container
    ModelSpace := Mb.ItemById("MS").Bind;
    // Get model
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    // Set mode of variable transfer for calculation
    TermInfo.Type := MsFormulaTermType.Pointwise;
    // Get expression of model calculation
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set expression of model calculation
    Expr.AsString := "CumulativeYTD(" + TermInfo.TermInnerText + ", MsCumulativeMethodType.Max, SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" +
        "), True)";
    // Check that expression is correct
    If Expr.Valid
        // If expression is set correctly, save model
        Then ModelObj.Save;
        // If expression is incorrect, display meassage to the console window
        Else Debug.WriteLine("Model is not saved: error in equation");
    End If;
End Sub UserProc;

After executing the example the model will transform variable using the Maximum cumulative method for the start of the year without taking into account missing data for the period from 2000 to 2015.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    // Get repository
    Mb := Params.Metabase;
    // Get modeling container
    ModelSpace := Mb.ItemById["MS"].Bind();
    // Get the model
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    // Get model calculation parameters
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    // Get the first input variable
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    // Set mode of passing variable into calculation
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    // Get model calculation expression
    Expr := Determ.Expression;
    Expr.References := "Ms";
    // Set model calculation expression
    Expr.AsString := "CumulativeYTD(" + TermInfo.TermInnerText + ", MsCumulativeMethodType.Max, SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" +
        "), True)";
    // Check if the expression is correct
    If Expr.Valid
        // If the expression is set correctly, save the model
        Then ModelObj.Save();
        // If the expression is incorrect, display a message to the console window
        Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in the formula");
    End If;
End Sub;

Example of Use in Expressions

Expression 1:

CumulativeYTD({Brazil|BCA[t]},MsCumulativeMethodType.Average, SetPeriod("01.01.2000", "01.01.2015"))

Result: accumulated average for the start of the year for the period from 2000 to 2015 will be calculated for the Brazil|BCA factor.

Use: it can be used in formulas of calculated series of time series database and in formulas of attribute-based models of modeling container.

Expression 2:

CumulativeYTD(X1,MsCumulativeMethodType.Sum)

Result: accumulated sum will be calculated for the X1 factor to the start of the year for the whole time period.

Use: it can be used in model variable-based formulas of modeling container.