IModelling.MovAvg

Fore Syntax

MovAvg(Input: ITimeSeries;
Period: IMsPeriod;
[WindowSize: Integer = 5;]

[Casewise: MsCasewise = 0]): Variant;

Fore.NET Syntax

MovAvg(Input: Prognoz.Platform.Interop.Ms.ITimeSeries;
Period: Prognoz.Platform.Interop.Ms.IMsPeriod;
WindowSize: integer;

Casewise: Prognoz.Platform.Interop.Ms.MsCasewise;
Context: Prognoz.Platform.Interop.Fore.ForeRuntimeContext): object;

Parameters

Input. Output variable.

Period. Period, at which the method is calculated. If the parameter is set to Null, the method is calculated at the entire time period.

WindowSize. Window size.

Casewise. Missing data treatment method.

Context. Context. The parameter is used only in Fore.NET.

Description

The MovAvg method transforms the variable by the moving averagemethod.

Comments

The moving average method is based on representing a series as a sum of a sufficiently smooth trend and a random component.

Fore Example

Executing the example requires that the repository contains a modeling container with the MS identifier. A model with the MODEL_D identifier calculated by the method of determinate equation and containing at least one input variable must be available in this container.

Add links to the Metabase, Ms system assemblies.

Sub ProcAvg;
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    Mb := MetabaseClass.Active;
    ModelSpace := Mb.ItemById("MS").Bind;
    ModelObj := Mb.ItemByIdNamespace("MODEL_D", ModelSpace.Key).Edit;
    Model := ModelObj As IMsModel;
    Transf := Model.Transform;
    Formula := Transf.FormulaItem(0);
    Determ := Formula.Method As IMsDeterministicTransform;
    TransVar := Transf.Inputs.Item(0);
    Slice := TransVar.Slices.Item(0);
    TermInfo := Transf.CreateTermInfo;
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.Pointwise;
    Expr := Determ.Expression;
    Expr.References := "Ms";
    Expr.AsString := "MovAvg(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "),  3, MsCasewise.Yes)";
    If Expr.Valid
        Then ModelObj.Save;
        Else Debug.WriteLine("The model is not saved: error in formula");
    End If;
End Sub ProcAvg;

After executing the example the model transforms the first input variable by moving average method at the period of 2000-2015. Calculation is executed using the Casewise missing data treatment method.

Fore.NET Example

The requirements and result of the Fore.NET example execution match with those in the Fore example.

Imports Prognoz.Platform.Interop.Ms;
Imports Prognoz.Platform.Interop.ForeSystem;
…
    [STAThread]
Public Shared Sub Main(Params: StartParams);
Var
    Mb: IMetabase;
    ModelSpace, ModelObj: IMetabaseObject;
    Transf: IMsFormulaTransform;
    Formula: IMsFormula;
    Model: IMsModel;
    Determ: IMsDeterministicTransform;
    TransVar: IMsFormulaTransformVariable;
    Slice: IMsFormulaTransformSlice;
    TermInfo: IMsFormulaTermInfo;
    Expr: IExpression;
Begin
    Mb := Params.Metabase;
    ModelSpace := Mb.ItemById["MS"].Bind();
    ModelObj := Mb.ItemByIdNamespace["MODEL_D", ModelSpace.Key].Edit();
    Model := ModelObj As IMsModel;
    Transf := Model.Transform;
    Formula := Transf.FormulaItem[0];
    Determ := Formula.Method As IMsDeterministicTransform;
    TransVar := Transf.Inputs.Item[0];
    Slice := TransVar.Slices.Item[0];
    TermInfo := Transf.CreateTermInfo();
    TermInfo.Slice := Slice;
    TermInfo.Type := MsFormulaTermType.mfttPointwise;
    Expr := Determ.Expression;
    Expr.References := "Ms";
    Expr.AsString := "MovAvg(" + TermInfo.TermInnerText + ", SetPeriod(" +
        """" + "01.01.2000" + """" + "," + """" + "01.01.2015" + """" + "),  3, MsCasewise.Yes)";
    If Expr.Valid
        Then ModelObj.Save();
        Else System.Diagnostics.Debug.WriteLine("Model is not saved: error in formula");
    End If;
End Sub;

Example of Use in Expressions

Expression 1:

MovAvg({Brazil|BCA}, SetPeriod("01.01.2000", "01.01.2015"), 3, MsCasewise.Yes)

Result: for the Brazil|BCA factor the method of moving average is applied with the window of 3 at the period of 2000-2015. Calculation is executed using the Casewise missing data treatment method.

Use: it can be used in formulas of calculated series of time series database and model formulas of modeling container that is a child of the time series database. The calculation is executed without considering missing values.

Expression 2:

MovAvg(X1, SetPeriod("01.01.1990", "01.01.2016"))

Result: for the X1 factor the moving average method is applied at the period of 1990-2016.

Use: it can be used in model formulas of modeling container.