IEaxMap.IndicatorElement

Fore Syntax

IndicatorElement(IndicatorType: EaxMapIndicatorType): Integer;

Fore.NET Syntax

IndicatorElement(IndicatorType: Prognoz.Platform.Interop.Express.EaxMapIndicatorType): Integer;

Parameters

IndicatorType. Type of the map factor to be associated with the element of data source dimension.

Description

The IndicatorElement property determines index of the dimension elements whose values will be used in the specified map factor.

Comments

This property associates a map factor to an element of factor dimension whose data is used as a specific dynamic characteristics of the territories. Factors dimension is defined in the IndicatorsDim property.

Fore Example

Executing the example requires an express report with the EXPRESS_REPORT identifier. Dimensions of the express report data source are based on the following dictionaries:

A dictionary with the identifier D_Indicators, that contains two elements. Data stored in these elements will determine map dynamics.
The territorial dictionary with the D_Map identifier.
The calendar dictionary with the Calendar identifier.

Sub UserProc;
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, TDim, TimeDim: IDimSelection;
    EMap: IEaxMap;
Begin
    MB := MetabaseClass.Active;
    Eax := MB.ItemById("EXPRESS_REPORT").Edit As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Dimensions search
    IDim := Selection.FindById("D_Indicators");
    TDim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Reset dimensions positions
    Pivot.LeftHeader.Clear;
    Pivot.TopHeader.Clear;
    //Selecting elements of the first calendar level
    TimeDim.SelectSiblings(0);
    //Set up map parameters
    EMap := Eax.Map;
    //Activate map
    EMap.Active := True;
    //Set up dimensions
    EMap.IndicatorsDim := IDim.Dimension;
    EMap.TerritoriesDim := TDim.Dimension;
    //Specify elements to be used to get values for map dimensions
    EMap.IndicatorElement(EaxMapIndicatorType.Color) := 0;
    EMap.IndicatorElement(EaxMapIndicatorType.Depth) := 1;
    //Save changes
    (Eax As IMetabaseObject).Save;
End Sub UserProc;

After executing the example the express report is set up for working with the map. Required location of dimensions is specified in express report and the required selection is specified by dimensions. Dimensions are specified for the map and elements are selected whose values should be used to get values for dynamic change of the map.

Fore.NET Example

Executing the example requires an express report with the EXPRESS_REPORT identifier. Dimensions of the express report data source are based on the following dictionaries:

A dictionary with the identifier D_Indicators, that contains two elements. Data stored in these elements will determine map dynamics.
The territorial dictionary with the D_Map identifier.
The calendar dictionary with the Calendar identifier.

The example is an entry point for a .NET assembly.

Imports Prognoz.Platform.Interop.Dimensions;
Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.Metabase;
Imports Prognoz.Platform.Interop.Pivot;

Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Eax: IEaxAnalyzer;
    Pivot: IPivot;
    Selection: IDimSelectionSet;
    IDim, TDim, TimeDim: IDimSelection;
    EMap: IEaxMap;
Begin
    MB := Params.Metabase;
    Eax := MB.ItemById["EXPRESS_REPORT"].Edit() As IEaxAnalyzer;
    Pivot := Eax.Pivot;
    Selection := Pivot.Selection;
    //Dimensions search
    IDim := Selection.FindById("D_Indicators");
    TDim := Selection.FindById("D_Map");
    TimeDim := Selection.FindById("Calendar");
    //Reset dimensions positions
    Pivot.LeftHeader.Clear();
    Pivot.TopHeader.Clear();
    //Selecting elements of the first calendar level
    TimeDim.SelectSiblings(0);
    //Set up map parameters
    EMap := Eax.Map;
    //Activate map
    EMap.Active := True;
    //Set up dimensions
    EMap.IndicatorsDim := IDim.Dimension;
    EMap.TerritoriesDim := TDim.Dimension;
    //Specify elements to be used to get values for map dimensions
    EMap.IndicatorElement[EaxMapIndicatorType.emitColor] := 0;
    EMap.IndicatorElement[EaxMapIndicatorType.emitDepth] := 1;
    //Save changes
    (Eax As IMetabaseObject).Save();
End Sub;

After executing this example the express report is set up for working with the map. Required location of dimensions is specified in express report and the required selection is specified by dimensions. Dimensions are specified for the map and elements are selected whose values should be used to get values for dynamic change of the map.