IEaxGridHeaderProperties.AutoIndent

Fore Syntax

AutoIndent: TriState;

Fore.NET Syntax

AutoIndent: Prognoz.Platform.Interop.ForeSystem.TriState;

Description

The AutoIndent property determines whether level element indents are used in the header.

Comments

If the property is set to TriState.OnOption, level element indents are used. If the value is TriState.OffOption, indents are not used.

If the property is set to undefined value TriState.Undefined, the use of indents is inherited from the parent header. The effective value taking into account the inheritance is returned by the IsAutoIndent property.

By default the property is set to TriState.Undefined.

Fore Example

Executing the example requires that the repository contains a regular report with the REPORT identifier. An analytical data area is created in the report.

Add links to the Express, Metabase, Pivot, Report system assemblies.

Sub UserProc;
Var
    MB: IMetabase;
    Report: IPrxReport;
    Grid: IEaxGrid;
    Slice: IEaxDataAreaPivotSlice;
    SettBase: IDataAreaHeaderSettingsBase;
    ViewSett: IEaxGridViewSettings;
    Props: IEaxGridHeaderProperties;
Begin
    // Get table
    MB := MetabaseClass.Active;
    Report := MB.ItemById("REPORT").Edit As IPrxReport;
    Grid := Report.DataArea.Views.Item(0) As IEaxGrid;
    // Get data analytical area slice
    Slice := Grid.Slice As IEaxDataAreaPivotSlice;
    // Get basic settings of sidehead headers
    SettBase := Slice.Pivot.LeftHeader As IDataAreaHeaderSettingsBase;
    // Get table view settings
    ViewSett := Grid.ViewSettings;
    // Change settings of level elements indents and expanders
    Props := ViewSett.GetViewSettings(SettBase) As IEaxGridHeaderProperties;
    Props.AutoIndent := Tristate.OffOption;
    Props.Hierarchical := Tristate.OffOption;
    Report.MetabaseObject.Save;
End Sub UserProc;

After executing the example the use of expanders and level element indents is disabled in analytical data area sidehead.

Fore.NET Example

The requirements and result of the Fore.NET Example execution match with those in the Fore Example.

Imports Prognoz.Platform.Interop.Express;
Imports Prognoz.Platform.Interop.ForeSystem;
Imports Prognoz.Platform.Interop.Pivot;
Imports Prognoz.Platform.Interop.Report;
…
Public Shared Sub Main(Params: StartParams);
Var
    MB: IMetabase;
    Report: IPrxReport;
    Grid: IEaxGrid;
    Slice: IEaxDataAreaPivotSlice;
    SettBase: IDataAreaHeaderSettingsBase;
    ViewSett: IEaxGridViewSettings;
    Props: IEaxGridHeaderProperties;
Begin
    // Get table
    MB := Params.Metabase;
    Report := MB.ItemById["REPORT"].Edit() As IPrxReport;
    Grid := Report.DataArea.Views.Item[0] As IEaxGrid;
    // Get analytical data area slice
    Slice := Grid.Slice As IEaxDataAreaPivotSlice;
    // Get basic settings of table sidehead headers
    SettBase := Slice.Pivot.LeftHeader As IDataAreaHeaderSettingsBase;
    // Get settings of table view
    ViewSett := Grid.ViewSettings;
    // Change settings of level element indents and expanders
    Props := ViewSett.GetViewSettings[SettBase] As IEaxGridHeaderProperties;
    Props.AutoIndent := Tristate.tsOffOption;
    Props.Hierarchical := Tristate.tsOffOption;
    Report.MetabaseObject.Save();
End Sub;