IVZPlacedControlBase.Style

Fore Syntax

Style: IVZControlStyle;

Fore.NET Syntax

Style: Prognoz.Platform.Interop.Visualizators.VZControlStyle;

Description

The Style property determines style for a control.

Fore Example

Executing the example requires that the repository contains an express report with the EXP identifier. The module containing the example should have links to the Drawing, Express, Metabase and Visualizators system assemblies. The selected procedure should be called from the Main entry point.

Before executing this example, the bubble tree looks as shown on the IVZBubbleTree interface description page. Set top and right border alignment and use turquoise color fill for bubble tree legend with intervals:

Sub UserProc;
Var
    Metabase: IMetabase; // Metabase
    Analyzer: IEaxAnalyzer; // Express report
    BubbleTree: IVZBubbleTree; // Bubble tree
    Style: IVZControlStyle; // Legend style
    Brush: IGxSolidBrush; // Brush
    Legend: IVZIntervalsLegend; // Legend with intervals
Begin       
    // Get metabase object
    Metabase := MetabaseClass.Active;
    // Open express report
    Analyzer := Metabase.ItemById("EXP").Edit As IEaxAnalyzer;
    // Get bubble tree
    BubbleTree := Analyzer.BubbleTree.BubbleTree;
    // Get legend with intervals
    Legend := BubbleTree.Legends.Item(0) As IVZIntervalsLegend;
    // Align legend horizontally
    Legend.HorizontalAlignment := VisualizatorHorizontalAlignment.Right;
    // Align legend vertically
    Legend.VerticalAlignment := VisualizatorVerticalAlignment.Top;
    // Set legend style with turquoise color fill
    Style := New VZControlStyle.Create;
    Brush := New GxSolidBrush.Create(New GxColor.CreateRGB(48, 213, 200));
    Style.Background := Brush;
    Legend.Style := Style;
    // Save changes, made in express report
    (Analyzer As IMetabaseObject).Save; 
End Sub UserProc;

After executing the example bubble tree legend with intervals is aligned at top and right borders, and filled with turquoise color:

Fore.NET Example

Executing the example requires that the repository contains an express report with the EXP identifier. The selected procedure is the Main entry point in the Program module of the .NET assembly. The Drawing, Express, Metabase and Visualizators assemblies should be imported to this module from the Prognoz.Platform.Interop system assembly.

Before executing this example, the bubble tree looks as shown on the IVZBubbleTree interface description page. Set top and right border alignment and use turquoise color fill for bubble tree legend with intervals:

Public Shared Sub Main(Params: StartParams);
Var
    Metabase: IMetabase; // Metabase
    Analyzer: IEaxAnalyzer; // Express report
    BubbleTree: IVZBubbleTree; // Bubble tree
    Style: IVZControlStyle = New VZControlStyle(); // Legend style
    Brush: IGxSolidBrush = New GxSolidBrush(); // Brush
    Color: IGxColor = New GxColor(); // Color
    Legend: IVZIntervalsLegend; // Legend with intervals
Begin       
    // Get metabase object
    Metabase := Params.Metabase;
    // Open express report
    Analyzer := Metabase.ItemById["EXP"].Edit() As IEaxAnalyzer;
    // Get bubble tree
    BubbleTree := Analyzer.BubbleTree.BubbleTree;
    // Get legend with intervals
    Legend := BubbleTree.Legends.Item[0] As IVZIntervalsLegend;
    // Align legend horizontally
    Legend.HorizontalAlignment := VisualizatorHorizontalAlignment.vhaRight;
    // Align legend vertically
    Legend.VerticalAlignment := VisualizatorVerticalAlignment.vvaTop;
    // Set legend style with turquoise color fill
    Color.CreateRGB(48, 213, 200);
    Brush.Color := Color As GxColor;
    Style.Background := Brush;
    Legend.Style := Style As VZControlStyle;
    // Save changes, made in express report
    (Analyzer As IMetabaseObject).Save();   
End Sub;

The result of the executed example is the same as that, executed for Fore language.

See also:

IVZPlacedControlBase